Git of dcc - anni/blob - lib/pleroma/object/containment.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2022 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Object.Containment do
   6   @moduledoc """
   7   This module contains some useful functions for containing objects to specific
   8   origins and determining those origins.  They previously lived in the
   9   ActivityPub `Transmogrifier` module.
  10
  11   Object containment is an important step in validating remote objects to prevent
  12   spoofing, therefore removal of object containment functions is NOT recommended.
  13   """
  14   def get_actor(%{"actor" => actor}) when is_binary(actor) do
  15     actor
  16   end
  17
  18   def get_actor(%{"actor" => actor}) when is_list(actor) do
  19     if is_binary(Enum.at(actor, 0)) do
  20       Enum.at(actor, 0)
  21     else
  22       Enum.find(actor, fn %{"type" => type} -> type in ["Person", "Service", "Application"] end)
  23       |> Map.get("id")
  24     end
  25   end
  26
  27   def get_actor(%{"actor" => %{"id" => id}}) when is_bitstring(id) do
  28     id
  29   end
  30
  31   def get_actor(%{"actor" => nil, "attributedTo" => actor}) when not is_nil(actor) do
  32     get_actor(%{"actor" => actor})
  33   end
  34
  35   def get_object(%{"object" => id}) when is_binary(id) do
  36     id
  37   end
  38
  39   def get_object(%{"object" => %{"id" => id}}) when is_binary(id) do
  40     id
  41   end
  42
  43   def get_object(_) do
  44     nil
  45   end
  46
  47   defp compare_uris(%URI{host: host} = _id_uri, %URI{host: host} = _other_uri), do: :ok
  48   defp compare_uris(_id_uri, _other_uri), do: :error
  49
  50   @doc """
  51   Checks that an imported AP object's actor matches the host it came from.
  52   """
  53   def contain_origin(_id, %{"actor" => nil}), do: :error
  54
  55   def contain_origin(id, %{"actor" => _actor} = params) do
  56     id_uri = URI.parse(id)
  57     actor_uri = URI.parse(get_actor(params))
  58
  59     compare_uris(actor_uri, id_uri)
  60   end
  61
  62   def contain_origin(id, %{"attributedTo" => actor} = params),
  63     do: contain_origin(id, Map.put(params, "actor", actor))
  64
  65   def contain_origin(_id, _data), do: :error
  66
  67   def contain_origin_from_id(id, %{"id" => other_id} = _params) when is_binary(other_id) do
  68     id_uri = URI.parse(id)
  69     other_uri = URI.parse(other_id)
  70
  71     compare_uris(id_uri, other_uri)
  72   end
  73
  74   # Mastodon pin activities don't have an id, so we check the object field, which will be pinned.
  75   def contain_origin_from_id(id, %{"object" => object}) when is_binary(object) do
  76     id_uri = URI.parse(id)
  77     object_uri = URI.parse(object)
  78
  79     compare_uris(id_uri, object_uri)
  80   end
  81
  82   def contain_origin_from_id(_id, _data), do: :error
  83
  84   def contain_child(%{"object" => %{"id" => id, "attributedTo" => _} = object}),
  85     do: contain_origin(id, object)
  86
  87   def contain_child(_), do: :ok
  88 end