Git of dcc - anni/blob - lib/pleroma/pagination.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2022 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Pagination do
   6   @moduledoc """
   7   Implements Mastodon-compatible pagination.
   8   """
   9
  10   import Ecto.Query
  11   import Ecto.Changeset
  12
  13   alias Pleroma.Repo
  14
  15   @type type :: :keyset | :offset
  16
  17   @default_limit 20
  18   @max_limit 40
  19   @page_keys ["max_id", "min_id", "limit", "since_id", "order"]
  20
  21   def page_keys, do: @page_keys
  22
  23   @spec fetch_paginated(Ecto.Query.t(), map(), type(), atom() | nil) :: [Ecto.Schema.t()]
  24   def fetch_paginated(query, params, type \\ :keyset, table_binding \\ nil)
  25
  26   def fetch_paginated(query, %{total: true} = params, :keyset, table_binding) do
  27     total = Repo.aggregate(query, :count, :id)
  28
  29     %{
  30       total: total,
  31       items: fetch_paginated(query, Map.drop(params, [:total]), :keyset, table_binding)
  32     }
  33   end
  34
  35   def fetch_paginated(query, params, :keyset, table_binding) do
  36     options = cast_params(params)
  37
  38     query
  39     |> paginate(options, :keyset, table_binding)
  40     |> Repo.all()
  41     |> enforce_order(options)
  42   end
  43
  44   def fetch_paginated(query, %{total: true} = params, :offset, table_binding) do
  45     total =
  46       query
  47       |> Ecto.Query.exclude(:left_join)
  48       |> Repo.aggregate(:count, :id)
  49
  50     %{
  51       total: total,
  52       items: fetch_paginated(query, Map.drop(params, [:total]), :offset, table_binding)
  53     }
  54   end
  55
  56   def fetch_paginated(query, params, :offset, table_binding) do
  57     options = cast_params(params)
  58
  59     query
  60     |> paginate(options, :offset, table_binding)
  61     |> Repo.all()
  62   end
  63
  64   @spec paginate_list(list(), keyword()) :: list()
  65   def paginate_list(list, options) do
  66     offset = options[:offset] || 0
  67     limit = options[:limit] || 0
  68     Enum.slice(list, offset, limit)
  69   end
  70
  71   @spec paginate(Ecto.Query.t(), map(), type(), atom() | nil) :: [Ecto.Schema.t()]
  72   def paginate(query, options, method \\ :keyset, table_binding \\ nil)
  73
  74   def paginate(query, options, :keyset, table_binding) do
  75     query
  76     |> restrict(:min_id, options, table_binding)
  77     |> restrict(:since_id, options, table_binding)
  78     |> restrict(:max_id, options, table_binding)
  79     |> restrict(:order, options, table_binding)
  80     |> restrict(:limit, options, table_binding)
  81   end
  82
  83   def paginate(query, options, :offset, table_binding) do
  84     query
  85     |> restrict(:order, options, table_binding)
  86     |> restrict(:offset, options, table_binding)
  87     |> restrict(:limit, options, table_binding)
  88   end
  89
  90   defp cast_params(params) do
  91     param_types = %{
  92       min_id: :string,
  93       since_id: :string,
  94       max_id: :string,
  95       offset: :integer,
  96       limit: :integer,
  97       skip_extra_order: :boolean,
  98       skip_order: :boolean
  99     }
 100
 101     changeset = cast({%{}, param_types}, params, Map.keys(param_types))
 102     changeset.changes
 103   end
 104
 105   defp restrict(query, :min_id, %{min_id: min_id}, table_binding) do
 106     where(query, [{q, table_position(query, table_binding)}], q.id > ^min_id)
 107   end
 108
 109   defp restrict(query, :since_id, %{since_id: since_id}, table_binding) do
 110     where(query, [{q, table_position(query, table_binding)}], q.id > ^since_id)
 111   end
 112
 113   defp restrict(query, :max_id, %{max_id: max_id}, table_binding) do
 114     where(query, [{q, table_position(query, table_binding)}], q.id < ^max_id)
 115   end
 116
 117   defp restrict(query, :order, %{skip_order: true}, _), do: query
 118
 119   defp restrict(%{order_bys: [_ | _]} = query, :order, %{skip_extra_order: true}, _), do: query
 120
 121   defp restrict(query, :order, %{min_id: _}, table_binding) do
 122     order_by(
 123       query,
 124       [{u, table_position(query, table_binding)}],
 125       fragment("? asc nulls last", u.id)
 126     )
 127   end
 128
 129   defp restrict(query, :order, _options, table_binding) do
 130     order_by(
 131       query,
 132       [{u, table_position(query, table_binding)}],
 133       fragment("? desc nulls last", u.id)
 134     )
 135   end
 136
 137   defp restrict(query, :offset, %{offset: offset}, _table_binding) do
 138     offset(query, ^offset)
 139   end
 140
 141   defp restrict(query, :limit, options, _table_binding) do
 142     limit =
 143       case Map.get(options, :limit, @default_limit) do
 144         limit when limit < @max_limit -> limit
 145         _ -> @max_limit
 146       end
 147
 148     query
 149     |> limit(^limit)
 150   end
 151
 152   defp restrict(query, _, _, _), do: query
 153
 154   defp enforce_order(result, %{min_id: _}) do
 155     result
 156     |> Enum.reverse()
 157   end
 158
 159   defp enforce_order(result, _), do: result
 160
 161   defp table_position(%Ecto.Query{} = query, binding_name) do
 162     Map.get(query.aliases, binding_name, 0)
 163   end
 164
 165   defp table_position(_, _), do: 0
 166 end