Git of dcc - anni/blob - lib/pleroma/web/activity_pub/object_validators/audio_image_video_validator.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2022 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.ObjectValidators.AudioImageVideoValidator do
   6   use Ecto.Schema
   7
   8   alias Pleroma.Web.ActivityPub.ObjectValidators.CommonFixes
   9   alias Pleroma.Web.ActivityPub.ObjectValidators.CommonValidations
  10   alias Pleroma.Web.ActivityPub.Transmogrifier
  11
  12   import Ecto.Changeset
  13
  14   @primary_key false
  15   @derive Jason.Encoder
  16
  17   embedded_schema do
  18     quote do
  19       unquote do
  20         import Elixir.Pleroma.Web.ActivityPub.ObjectValidators.CommonFields
  21         message_fields()
  22         object_fields()
  23         status_object_fields()
  24       end
  25     end
  26   end
  27
  28   def cast_and_apply(data) do
  29     data
  30     |> cast_data
  31     |> apply_action(:insert)
  32   end
  33
  34   def cast_and_validate(data) do
  35     data
  36     |> cast_data()
  37     |> validate_data()
  38   end
  39
  40   def cast_data(data) do
  41     %__MODULE__{}
  42     |> changeset(data)
  43   end
  44
  45   defp find_attachment(url) do
  46     mpeg_url =
  47       Enum.find(url, fn
  48         %{"mediaType" => mime_type, "tag" => tags} when is_list(tags) ->
  49           mime_type == "application/x-mpegURL"
  50
  51         _ ->
  52           false
  53       end)
  54
  55     url
  56     |> Enum.concat(mpeg_url["tag"] || [])
  57     |> Enum.find(fn
  58       %{"mediaType" => mime_type} ->
  59         String.starts_with?(mime_type, ["video/", "audio/", "image/"])
  60
  61       %{"mimeType" => mime_type} ->
  62         String.starts_with?(mime_type, ["video/", "audio/", "image/"])
  63
  64       _ ->
  65         false
  66     end)
  67   end
  68
  69   defp fix_url(%{"url" => url} = data) when is_list(url) do
  70     attachment = find_attachment(url)
  71
  72     link_element =
  73       Enum.find(url, fn
  74         %{"mediaType" => "text/html"} -> true
  75         %{"mimeType" => "text/html"} -> true
  76         _ -> false
  77       end)
  78
  79     data
  80     |> Map.put("attachment", [attachment])
  81     |> Map.put("url", link_element["href"])
  82   end
  83
  84   defp fix_url(data), do: data
  85
  86   defp fix_content(%{"mediaType" => "text/markdown", "content" => content} = data)
  87        when is_binary(content) do
  88     content =
  89       content
  90       |> Pleroma.Formatter.markdown_to_html()
  91       |> Pleroma.HTML.filter_tags()
  92
  93     Map.put(data, "content", content)
  94   end
  95
  96   defp fix_content(data), do: data
  97
  98   defp fix(data) do
  99     data
 100     |> CommonFixes.fix_actor()
 101     |> CommonFixes.fix_object_defaults()
 102     |> CommonFixes.fix_quote_url()
 103     |> Transmogrifier.fix_emoji()
 104     |> fix_url()
 105     |> fix_content()
 106   end
 107
 108   def changeset(struct, data) do
 109     data = fix(data)
 110
 111     struct
 112     |> cast(data, __schema__(:fields) -- [:attachment, :tag])
 113     |> cast_embed(:attachment, required: true)
 114     |> cast_embed(:tag)
 115   end
 116
 117   defp validate_data(data_cng) do
 118     data_cng
 119     |> validate_inclusion(:type, ~w[Audio Image Video])
 120     |> validate_required([:id, :actor, :attributedTo, :type, :context])
 121     |> CommonValidations.validate_any_presence([:cc, :to])
 122     |> CommonValidations.validate_fields_match([:actor, :attributedTo])
 123     |> CommonValidations.validate_actor_presence()
 124     |> CommonValidations.validate_host_match()
 125   end
 126 end