Git of dcc - anni/blob - lib/pleroma/web/activity_pub/object_validators/emoji_react_validator.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2022 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.ObjectValidators.EmojiReactValidator do
   6   use Ecto.Schema
   7
   8   alias Pleroma.Emoji
   9   alias Pleroma.Object
  10   alias Pleroma.Web.ActivityPub.ObjectValidators.CommonFixes
  11   alias Pleroma.Web.ActivityPub.ObjectValidators.TagValidator
  12
  13   import Ecto.Changeset
  14   import Pleroma.Web.ActivityPub.ObjectValidators.CommonValidations
  15
  16   @primary_key false
  17
  18   embedded_schema do
  19     quote do
  20       unquote do
  21         import Elixir.Pleroma.Web.ActivityPub.ObjectValidators.CommonFields
  22         message_fields()
  23         activity_fields()
  24         embeds_many(:tag, TagValidator)
  25       end
  26     end
  27
  28     field(:context, :string)
  29     field(:content, :string)
  30   end
  31
  32   def cast_and_validate(data) do
  33     data
  34     |> cast_data()
  35     |> validate_data()
  36   end
  37
  38   def cast_data(data) do
  39     data =
  40       data
  41       |> fix()
  42
  43     %__MODULE__{}
  44     |> changeset(data)
  45   end
  46
  47   def changeset(struct, data) do
  48     struct
  49     |> cast(data, __schema__(:fields) -- [:tag])
  50     |> cast_embed(:tag)
  51   end
  52
  53   defp fix(data) do
  54     data =
  55       data
  56       |> fix_emoji_qualification()
  57       |> CommonFixes.fix_actor()
  58       |> CommonFixes.fix_activity_addressing()
  59
  60     data = Map.put_new(data, "tag", [])
  61
  62     case Object.normalize(data["object"]) do
  63       %Object{} = object ->
  64         data
  65         |> CommonFixes.fix_activity_context(object)
  66         |> CommonFixes.fix_object_action_recipients(object)
  67
  68       _ ->
  69         data
  70     end
  71   end
  72
  73   defp fix_emoji_qualification(%{"content" => emoji} = data) do
  74     new_emoji = Pleroma.Emoji.fully_qualify_emoji(emoji)
  75
  76     cond do
  77       Pleroma.Emoji.unicode?(emoji) ->
  78         data
  79
  80       Pleroma.Emoji.unicode?(new_emoji) ->
  81         data |> Map.put("content", new_emoji)
  82
  83       true ->
  84         data
  85     end
  86   end
  87
  88   defp fix_emoji_qualification(data), do: data
  89
  90   defp validate_emoji(cng) do
  91     content = get_field(cng, :content)
  92
  93     if Emoji.unicode?(content) || Emoji.custom?(content) do
  94       cng
  95     else
  96       cng
  97       |> add_error(:content, "is not a valid emoji")
  98     end
  99   end
 100
 101   defp maybe_validate_tag_presence(cng) do
 102     content = get_field(cng, :content)
 103
 104     if Emoji.unicode?(content) do
 105       cng
 106     else
 107       tag = get_field(cng, :tag)
 108       emoji_name = Emoji.maybe_strip_name(content)
 109
 110       case tag do
 111         [%{name: ^emoji_name, type: "Emoji", icon: %{url: _}}] ->
 112           cng
 113
 114         _ ->
 115           cng
 116           |> add_error(:tag, "does not contain an Emoji tag")
 117       end
 118     end
 119   end
 120
 121   defp validate_data(data_cng) do
 122     data_cng
 123     |> validate_inclusion(:type, ["EmojiReact"])
 124     |> validate_required([:id, :type, :object, :actor, :context, :to, :cc, :content])
 125     |> validate_actor_presence()
 126     |> validate_object_presence()
 127     |> validate_emoji()
 128     |> maybe_validate_tag_presence()
 129   end
 130 end