Git of dcc - anni/blob - lib/pleroma/web/controller_helper.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2022 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ControllerHelper do
   6   use Pleroma.Web, :controller
   7
   8   alias Pleroma.Pagination
   9   alias Pleroma.Web.Utils.Params
  10
  11   def json_response(conn, status, _) when status in [204, :no_content] do
  12     conn
  13     |> put_resp_header("content-type", "application/json")
  14     |> send_resp(status, "")
  15   end
  16
  17   def json_response(conn, status, json) do
  18     conn
  19     |> put_status(status)
  20     |> json(json)
  21   end
  22
  23   @spec fetch_integer_param(map(), String.t() | atom(), integer() | nil) :: integer() | nil
  24   def fetch_integer_param(params, name, default \\ nil) do
  25     params
  26     |> Map.get(name, default)
  27     |> param_to_integer(default)
  28   end
  29
  30   defp param_to_integer(val, _) when is_integer(val), do: val
  31
  32   defp param_to_integer(val, default) when is_binary(val) do
  33     case Integer.parse(val) do
  34       {res, _} -> res
  35       _ -> default
  36     end
  37   end
  38
  39   defp param_to_integer(_, default), do: default
  40
  41   def add_link_headers(conn, entries, extra_params \\ %{})
  42
  43   def add_link_headers(%{assigns: %{skip_link_headers: true}} = conn, _entries, _extra_params),
  44     do: conn
  45
  46   def add_link_headers(conn, entries, extra_params) do
  47     case get_pagination_fields(conn, entries, extra_params) do
  48       %{"next" => next_url, "prev" => prev_url} ->
  49         put_resp_header(conn, "link", "<#{next_url}>; rel=\"next\", <#{prev_url}>; rel=\"prev\"")
  50
  51       _ ->
  52         conn
  53     end
  54   end
  55
  56   # TODO: Only fetch the params from open_api_spex when everything is converted
  57   @id_keys Pagination.page_keys() -- ["limit", "order"]
  58   defp build_pagination_fields(conn, min_id, max_id, extra_params) do
  59     params =
  60       if Map.has_key?(conn.private, :open_api_spex) do
  61         get_in(conn, [Access.key(:private), Access.key(:open_api_spex), Access.key(:params)])
  62       else
  63         conn.params
  64       end
  65       |> Map.drop(Map.keys(conn.path_params) |> Enum.map(&String.to_existing_atom/1))
  66       |> Map.merge(extra_params)
  67       |> Map.drop(@id_keys)
  68
  69     %{
  70       "next" => current_url(conn, Map.put(params, :max_id, max_id)),
  71       "prev" => current_url(conn, Map.put(params, :min_id, min_id)),
  72       "id" => current_url(conn)
  73     }
  74   end
  75
  76   def get_pagination_fields(conn, entries, extra_params \\ %{}) do
  77     case List.last(entries) do
  78       %{pagination_id: max_id} when not is_nil(max_id) ->
  79         %{pagination_id: min_id} = List.first(entries)
  80
  81         build_pagination_fields(conn, min_id, max_id, extra_params)
  82
  83       %{id: max_id} ->
  84         %{id: min_id} = List.first(entries)
  85
  86         build_pagination_fields(conn, min_id, max_id, extra_params)
  87
  88       _ ->
  89         %{}
  90     end
  91   end
  92
  93   def assign_account_by_id(%{private: %{open_api_spex: %{params: %{id: id}}}} = conn, _) do
  94     case Pleroma.User.get_cached_by_id(id) do
  95       %Pleroma.User{} = account -> assign(conn, :account, account)
  96       nil -> Pleroma.Web.MastodonAPI.FallbackController.call(conn, {:error, :not_found}) |> halt()
  97     end
  98   end
  99
 100   def try_render(conn, target, params) when is_binary(target) do
 101     render(conn, target, params)
 102   end
 103
 104   def try_render(conn, _, _) do
 105     render_error(conn, :not_implemented, "Can't display this activity")
 106   end
 107
 108   @doc """
 109   Returns true if request specifies to include embedded relationships in account objects.
 110   May only be used in selected account-related endpoints; has no effect for status- or
 111     notification-related endpoints.
 112   """
 113   # Intended for PleromaFE: https://git.pleroma.social/pleroma/pleroma-fe/-/issues/838
 114   def embed_relationships?(params) do
 115     # To do once OpenAPI transition mess is over: just `truthy_param?(params[:with_relationships])`
 116     params
 117     |> Map.get(:with_relationships, params["with_relationships"])
 118     |> Params.truthy_param?()
 119   end
 120 end