Git of dcc - anni/blob - lib/pleroma/web/pleroma_api/controllers/emoji_reaction_controller.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2022 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.PleromaAPI.EmojiReactionController do
   6   use Pleroma.Web, :controller
   7
   8   alias Pleroma.Activity
   9   alias Pleroma.Object
  10   alias Pleroma.User
  11   alias Pleroma.Web.CommonAPI
  12   alias Pleroma.Web.MastodonAPI.StatusView
  13   alias Pleroma.Web.Plugs.OAuthScopesPlug
  14
  15   plug(Pleroma.Web.ApiSpec.CastAndValidate)
  16   plug(OAuthScopesPlug, %{scopes: ["write:statuses"]} when action in [:create, :delete])
  17
  18   plug(
  19     OAuthScopesPlug,
  20     %{scopes: ["read:statuses"], fallback: :proceed_unauthenticated}
  21     when action == :index
  22   )
  23
  24   defdelegate open_api_operation(action), to: Pleroma.Web.ApiSpec.EmojiReactionOperation
  25
  26   action_fallback(Pleroma.Web.MastodonAPI.FallbackController)
  27
  28   def index(%{assigns: %{user: user}} = conn, %{id: activity_id} = params) do
  29     with true <- Pleroma.Config.get([:instance, :show_reactions]),
  30          %Activity{} = activity <- Activity.get_by_id_with_object(activity_id),
  31          %Object{} = object <- Object.normalize(activity, fetch: false),
  32          reactions <- Object.get_emoji_reactions(object) do
  33       reactions =
  34         reactions
  35         |> filter(params)
  36         |> filter_allowed_users(user, Map.get(params, :with_muted, false))
  37
  38       render(conn, "index.json", emoji_reactions: reactions, user: user)
  39     else
  40       _e -> json(conn, [])
  41     end
  42   end
  43
  44   def filter_allowed_users(reactions, user, with_muted) do
  45     exclude_ap_ids =
  46       if is_nil(user) do
  47         []
  48       else
  49         User.cached_blocked_users_ap_ids(user) ++
  50           if not with_muted, do: User.cached_muted_users_ap_ids(user), else: []
  51       end
  52
  53     filter_emoji = fn emoji, users, url ->
  54       case Enum.reject(users, &(&1 in exclude_ap_ids)) do
  55         [] -> nil
  56         users -> {emoji, users, url}
  57       end
  58     end
  59
  60     reactions
  61     |> Stream.map(fn
  62       [emoji, users, url] when is_list(users) -> filter_emoji.(emoji, users, url)
  63     end)
  64     |> Stream.reject(&is_nil/1)
  65   end
  66
  67   defp filter(reactions, %{emoji: emoji}) when is_binary(emoji) do
  68     Enum.filter(reactions, fn [e, _, _] -> e == emoji end)
  69   end
  70
  71   defp filter(reactions, _), do: reactions
  72
  73   def create(%{assigns: %{user: user}} = conn, %{id: activity_id, emoji: emoji}) do
  74     emoji =
  75       emoji
  76       |> Pleroma.Emoji.fully_qualify_emoji()
  77       |> Pleroma.Emoji.maybe_quote()
  78
  79     with {:ok, _activity} <- CommonAPI.react_with_emoji(activity_id, user, emoji) do
  80       activity = Activity.get_by_id(activity_id)
  81
  82       conn
  83       |> put_view(StatusView)
  84       |> render("show.json", activity: activity, for: user, as: :activity)
  85     end
  86   end
  87
  88   def delete(%{assigns: %{user: user}} = conn, %{id: activity_id, emoji: emoji}) do
  89     emoji =
  90       emoji
  91       |> Pleroma.Emoji.fully_qualify_emoji()
  92       |> Pleroma.Emoji.maybe_quote()
  93
  94     with {:ok, _activity} <- CommonAPI.unreact_with_emoji(activity_id, user, emoji) do
  95       activity = Activity.get_by_id(activity_id)
  96
  97       conn
  98       |> put_view(StatusView)
  99       |> render("show.json", activity: activity, for: user, as: :activity)
 100     end
 101   end
 102 end