Git of dcc - anni/blob - lib/pleroma/web/pleroma_api/views/chat/message_reference_view.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2022 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.PleromaAPI.Chat.MessageReferenceView do
   6   use Pleroma.Web, :view
   7
   8   alias Pleroma.Maps
   9   alias Pleroma.User
  10   alias Pleroma.Web.CommonAPI.Utils
  11   alias Pleroma.Web.MastodonAPI.StatusView
  12   alias Pleroma.Web.RichMedia.Card
  13
  14   @cachex Pleroma.Config.get([:cachex, :provider], Cachex)
  15
  16   def render(
  17         "show.json",
  18         %{
  19           chat_message_reference: %{
  20             id: id,
  21             object: %{data: chat_message} = object,
  22             chat_id: chat_id,
  23             unread: unread
  24           }
  25         }
  26       ) do
  27     card =
  28       case Card.get_by_object(object) do
  29         %Card{} = card_data -> StatusView.render("card.json", card_data)
  30         _ -> nil
  31       end
  32
  33     %{
  34       id: id |> to_string(),
  35       content: chat_message["content"],
  36       chat_id: chat_id |> to_string(),
  37       account_id: User.get_cached_by_ap_id(chat_message["actor"]).id,
  38       created_at: Utils.to_masto_date(chat_message["published"]),
  39       emojis: StatusView.build_emojis(chat_message["emoji"]),
  40       attachment:
  41         chat_message["attachment"] &&
  42           StatusView.render("attachment.json", attachment: chat_message["attachment"]),
  43       unread: unread,
  44       card: card
  45     }
  46     |> put_idempotency_key()
  47   end
  48
  49   def render("index.json", opts) do
  50     render_many(
  51       opts[:chat_message_references],
  52       __MODULE__,
  53       "show.json",
  54       Map.put(opts, :as, :chat_message_reference)
  55     )
  56   end
  57
  58   defp put_idempotency_key(data) do
  59     with {:ok, idempotency_key} <- @cachex.get(:chat_message_id_idempotency_key_cache, data.id) do
  60       data
  61       |> Maps.put_if_present(:idempotency_key, idempotency_key)
  62     else
  63       _ -> data
  64     end
  65   end
  66 end