Git of dcc - anni/blob - lib/pleroma/web/pleroma_api/views/chat_view.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2022 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.PleromaAPI.ChatView do
   6   use Pleroma.Web, :view
   7
   8   alias Pleroma.Chat
   9   alias Pleroma.Chat.MessageReference
  10   alias Pleroma.User
  11   alias Pleroma.Web.CommonAPI.Utils
  12   alias Pleroma.Web.MastodonAPI.AccountView
  13   alias Pleroma.Web.PleromaAPI.Chat.MessageReferenceView
  14
  15   def render("show.json", %{chat: %Chat{} = chat} = opts) do
  16     recipient = User.get_cached_by_ap_id(chat.recipient)
  17     last_message = opts[:last_message] || MessageReference.last_message_for_chat(chat)
  18     account_view_opts = account_view_opts(opts, recipient)
  19
  20     %{
  21       id: chat.id |> to_string(),
  22       account: AccountView.render("show.json", account_view_opts),
  23       unread: MessageReference.unread_count_for_chat(chat),
  24       last_message:
  25         last_message &&
  26           MessageReferenceView.render("show.json", chat_message_reference: last_message),
  27       updated_at: Utils.to_masto_date(chat.updated_at)
  28     }
  29   end
  30
  31   def render("index.json", %{chats: chats} = opts) do
  32     render_many(chats, __MODULE__, "show.json", Map.delete(opts, :chats))
  33   end
  34
  35   defp account_view_opts(opts, recipient) do
  36     account_view_opts = Map.put(opts, :user, recipient)
  37
  38     if Map.has_key?(account_view_opts, :for) do
  39       account_view_opts
  40     else
  41       Map.put(account_view_opts, :skip_visibility_check, true)
  42     end
  43   end
  44 end