Git of dcc - anni/blob - test/pleroma/activity/search_test.exs

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2022 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Activity.SearchTest do
   6   alias Pleroma.Activity.Search
   7   alias Pleroma.Web.CommonAPI
   8   import Pleroma.Factory
   9
  10   use Pleroma.DataCase, async: true
  11
  12   test "it finds something" do
  13     user = insert(:user)
  14     {:ok, post} = CommonAPI.post(user, %{status: "it's wednesday my dudes"})
  15
  16     [result] = Search.search(nil, "wednesday")
  17
  18     assert result.id == post.id
  19   end
  20
  21   test "it finds local-only posts for authenticated users" do
  22     user = insert(:user)
  23     reader = insert(:user)
  24     {:ok, post} = CommonAPI.post(user, %{status: "it's wednesday my dudes", visibility: "local"})
  25
  26     [result] = Search.search(reader, "wednesday")
  27
  28     assert result.id == post.id
  29   end
  30
  31   test "it does not find local-only posts for anonymous users" do
  32     user = insert(:user)
  33     {:ok, _post} = CommonAPI.post(user, %{status: "it's wednesday my dudes", visibility: "local"})
  34
  35     assert [] = Search.search(nil, "wednesday")
  36   end
  37
  38   test "using plainto_tsquery on postgres < 11" do
  39     old_version = :persistent_term.get({Pleroma.Repo, :postgres_version})
  40     :persistent_term.put({Pleroma.Repo, :postgres_version}, 10.0)
  41     on_exit(fn -> :persistent_term.put({Pleroma.Repo, :postgres_version}, old_version) end)
  42
  43     user = insert(:user)
  44     {:ok, post} = CommonAPI.post(user, %{status: "it's wednesday my dudes"})
  45     {:ok, _post2} = CommonAPI.post(user, %{status: "it's wednesday my bros"})
  46
  47     # plainto doesn't understand complex queries
  48     assert [result] = Search.search(nil, "wednesday -dudes")
  49
  50     assert result.id == post.id
  51   end
  52
  53   test "using websearch_to_tsquery" do
  54     user = insert(:user)
  55     {:ok, _post} = CommonAPI.post(user, %{status: "it's wednesday my dudes"})
  56     {:ok, other_post} = CommonAPI.post(user, %{status: "it's wednesday my bros"})
  57
  58     assert [result] = Search.search(nil, "wednesday -dudes")
  59
  60     assert result.id == other_post.id
  61   end
  62 end