Git of dcc - anni/blob - lib/pleroma/emoji/loader.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2022 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Emoji.Loader do
   6   @moduledoc """
   7   The Loader emoji from:
   8
   9     * emoji packs in INSTANCE-DIR/emoji
  10     * the files: `config/emoji.txt` and `config/custom_emoji.txt`
  11     * glob paths, nested folder is used as tag name for grouping e.g. priv/static/emoji/custom/nested_folder
  12   """
  13   alias Pleroma.Config
  14   alias Pleroma.Emoji
  15
  16   require Logger
  17
  18   @type pattern :: Regex.t() | module() | String.t()
  19   @type patterns :: pattern() | [pattern()]
  20   @type group_patterns :: keyword(patterns())
  21   @type emoji :: {String.t(), Emoji.t()}
  22
  23   @doc """
  24   Loads emojis from files/packs.
  25
  26   returns list emojis in format:
  27   `{"000", "/emoji/freespeechextremist.com/000.png", ["Custom"]}`
  28   """
  29   @spec load() :: list(emoji)
  30   def load do
  31     emoji_dir_path = Path.join(Config.get!([:instance, :static_dir]), "emoji")
  32
  33     emoji_groups = Config.get([:emoji, :groups])
  34
  35     emojis =
  36       case File.ls(emoji_dir_path) do
  37         {:error, :enoent} ->
  38           # The custom emoji directory doesn't exist,
  39           # don't do anything
  40           []
  41
  42         {:error, e} ->
  43           # There was some other error
  44           Logger.error("Could not access the custom emoji directory #{emoji_dir_path}: #{e}")
  45           []
  46
  47         {:ok, results} ->
  48           grouped =
  49             Enum.group_by(results, fn file ->
  50               File.dir?(Path.join(emoji_dir_path, file))
  51             end)
  52
  53           packs = grouped[true] || []
  54           files = grouped[false] || []
  55
  56           # Print the packs we've found
  57           Logger.info("Found emoji packs: #{Enum.join(packs, ", ")}")
  58
  59           if not Enum.empty?(files) do
  60             Logger.warning(
  61               "Found files in the emoji folder. These will be ignored, please move them to a subdirectory\nFound files: #{Enum.join(files, ", ")}"
  62             )
  63           end
  64
  65           emojis =
  66             Enum.flat_map(packs, fn pack ->
  67               load_pack(Path.join(emoji_dir_path, pack), emoji_groups)
  68             end)
  69
  70           Emoji.clear_all()
  71           emojis
  72       end
  73
  74     # Compat thing for old custom emoji handling & default emoji,
  75     # it should run even if there are no emoji packs
  76     shortcode_globs = Config.get([:emoji, :shortcode_globs], [])
  77
  78     # for testing emoji.txt entries we do not want exposed in normal operation
  79     test_emoji =
  80       if Application.get_env(:pleroma, __MODULE__)[:test_emoji] do
  81         load_from_file("test/config/emoji.txt", emoji_groups)
  82       else
  83         []
  84       end
  85
  86     emojis_txt =
  87       (load_from_file("config/emoji.txt", emoji_groups) ++
  88          load_from_file("config/custom_emoji.txt", emoji_groups) ++
  89          load_from_globs(shortcode_globs, emoji_groups) ++
  90          test_emoji)
  91       |> Enum.reject(fn value -> value == nil end)
  92
  93     Enum.map(emojis ++ emojis_txt, &prepare_emoji/1)
  94   end
  95
  96   defp prepare_emoji({code, _, _} = emoji), do: {code, Emoji.build(emoji)}
  97
  98   defp load_pack(pack_dir, emoji_groups) do
  99     pack_name = Path.basename(pack_dir)
 100
 101     pack_file = Path.join(pack_dir, "pack.json")
 102
 103     if File.exists?(pack_file) do
 104       Logger.info("Loading emoji pack from JSON: #{pack_file}")
 105       contents = Jason.decode!(File.read!(pack_file))
 106
 107       contents["files"]
 108       |> Enum.map(fn {name, rel_file} ->
 109         filename = Path.join("/emoji/#{pack_name}", rel_file)
 110         {name, filename, ["pack:#{pack_name}"]}
 111       end)
 112     else
 113       # Load from emoji.txt / all files
 114       emoji_txt = Path.join(pack_dir, "emoji.txt")
 115
 116       if File.exists?(emoji_txt) do
 117         Logger.info("Loading emoji pack from emoji.txt: #{emoji_txt}")
 118         load_from_file(emoji_txt, emoji_groups)
 119       else
 120         extensions = Config.get([:emoji, :pack_extensions])
 121
 122         Logger.info(
 123           "No emoji.txt found for pack \"#{pack_name}\", assuming all #{Enum.join(extensions, ", ")} files are emoji"
 124         )
 125
 126         make_shortcode_to_file_map(pack_dir, extensions)
 127         |> Enum.map(fn {shortcode, rel_file} ->
 128           filename = Path.join("/emoji/#{pack_name}", rel_file)
 129
 130           {shortcode, filename, [to_string(match_extra(emoji_groups, filename))]}
 131         end)
 132       end
 133     end
 134   end
 135
 136   def make_shortcode_to_file_map(pack_dir, exts) do
 137     find_all_emoji(pack_dir, exts)
 138     |> Enum.map(&Path.relative_to(&1, pack_dir))
 139     |> Enum.map(fn f -> {f |> Path.basename() |> Path.rootname(), f} end)
 140     |> Enum.into(%{})
 141   end
 142
 143   def find_all_emoji(dir, exts) do
 144     dir
 145     |> File.ls!()
 146     |> Enum.flat_map(fn f ->
 147       filepath = Path.join(dir, f)
 148
 149       if File.dir?(filepath) do
 150         find_all_emoji(filepath, exts)
 151       else
 152         [filepath]
 153       end
 154     end)
 155     |> Enum.filter(fn f -> Path.extname(f) in exts end)
 156   end
 157
 158   defp load_from_file(file, emoji_groups) do
 159     if File.exists?(file) do
 160       load_from_file_stream(File.stream!(file), emoji_groups)
 161     else
 162       []
 163     end
 164   end
 165
 166   defp load_from_file_stream(stream, emoji_groups) do
 167     stream
 168     |> Stream.map(&String.trim/1)
 169     |> Stream.map(fn line ->
 170       case String.split(line, ~r/,\s*/) do
 171         [name, file] ->
 172           {name, file, [to_string(match_extra(emoji_groups, file))]}
 173
 174         [name, file | tags] ->
 175           {name, file, tags}
 176
 177         _ ->
 178           nil
 179       end
 180     end)
 181     |> Enum.to_list()
 182   end
 183
 184   defp load_from_globs(globs, emoji_groups) do
 185     static_path = Path.join(:code.priv_dir(:pleroma), "static")
 186
 187     paths =
 188       Enum.map(globs, fn glob ->
 189         Path.join(static_path, glob)
 190         |> Path.wildcard()
 191       end)
 192       |> Enum.concat()
 193
 194     Enum.map(paths, fn path ->
 195       tag = match_extra(emoji_groups, Path.join("/", Path.relative_to(path, static_path)))
 196       shortcode = Path.basename(path, Path.extname(path))
 197       external_path = Path.join("/", Path.relative_to(path, static_path))
 198       {shortcode, external_path, [to_string(tag)]}
 199     end)
 200   end
 201
 202   @doc """
 203   Finds a matching group for the given emoji filename
 204   """
 205   @spec match_extra(group_patterns(), String.t()) :: atom() | nil
 206   def match_extra(group_patterns, filename) do
 207     match_group_patterns(group_patterns, fn pattern ->
 208       case pattern do
 209         %Regex{} = regex -> Regex.match?(regex, filename)
 210         string when is_binary(string) -> filename == string
 211       end
 212     end)
 213   end
 214
 215   defp match_group_patterns(group_patterns, matcher) do
 216     Enum.find_value(group_patterns, fn {group, patterns} ->
 217       patterns =
 218         patterns
 219         |> List.wrap()
 220         |> Enum.map(fn pattern ->
 221           if String.contains?(pattern, "*") do
 222             ~r(#{String.replace(pattern, "*", ".*")})
 223           else
 224             pattern
 225           end
 226         end)
 227
 228       Enum.any?(patterns, matcher) && group
 229     end)
 230   end
 231 end