Git of dcc - anni/blob - lib/pleroma/upload.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2022 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Upload do
   6   @moduledoc """
   7   Manage user uploads
   8
   9   Options:
  10   * `:type`: presets for activity type (defaults to Document) and size limits from app configuration
  11   * `:description`: upload alternative text
  12   * `:base_url`: override base url
  13   * `:uploader`: override uploader
  14   * `:filters`: override filters
  15   * `:size_limit`: override size limit
  16   * `:activity_type`: override activity type
  17
  18   The `%Pleroma.Upload{}` struct: all documented fields are meant to be overwritten in filters:
  19
  20   * `:id` - the upload id.
  21   * `:name` - the upload file name.
  22   * `:path` - the upload path: set at first to `id/name` but can be changed. Keep in mind that the path
  23     is once created permanent and changing it (especially in uploaders) is probably a bad idea!
  24   * `:tempfile` - path to the temporary file. Prefer in-place changes on the file rather than changing the
  25   path as the temporary file is also tracked by `Plug.Upload{}` and automatically deleted once the request is over.
  26   * `:width` - width of the media in pixels
  27   * `:height` - height of the media in pixels
  28   * `:blurhash` - string hash of the image encoded with the blurhash algorithm (https://blurha.sh/)
  29
  30   Related behaviors:
  31
  32   * `Pleroma.Uploaders.Uploader`
  33   * `Pleroma.Upload.Filter`
  34
  35   """
  36   alias Ecto.UUID
  37   alias Pleroma.Maps
  38   alias Pleroma.Web.ActivityPub.Utils
  39   require Logger
  40
  41   @type source ::
  42           Plug.Upload.t()
  43           | (data_uri_string :: String.t())
  44           | {:from_local, name :: String.t(), id :: String.t(), path :: String.t()}
  45           | map()
  46
  47   @type option ::
  48           {:type, :avatar | :banner | :background}
  49           | {:description, String.t()}
  50           | {:activity_type, String.t()}
  51           | {:size_limit, nil | non_neg_integer()}
  52           | {:uploader, module()}
  53           | {:filters, [module()]}
  54           | {:actor, String.t()}
  55
  56   @type t :: %__MODULE__{
  57           id: String.t(),
  58           name: String.t(),
  59           tempfile: String.t(),
  60           content_type: String.t(),
  61           width: integer(),
  62           height: integer(),
  63           blurhash: String.t(),
  64           description: String.t(),
  65           path: String.t()
  66         }
  67   defstruct [
  68     :id,
  69     :name,
  70     :tempfile,
  71     :content_type,
  72     :width,
  73     :height,
  74     :blurhash,
  75     :description,
  76     :path
  77   ]
  78
  79   @config_impl Application.compile_env(:pleroma, [__MODULE__, :config_impl], Pleroma.Config)
  80
  81   defp get_description(upload) do
  82     case {upload.description, Pleroma.Config.get([Pleroma.Upload, :default_description])} do
  83       {description, _} when is_binary(description) -> description
  84       {_, :filename} -> upload.name
  85       {_, str} when is_binary(str) -> str
  86       _ -> ""
  87     end
  88   end
  89
  90   @spec store(source, options :: [option()]) :: {:ok, map()} | {:error, any()}
  91   @doc "Store a file. If using a `Plug.Upload{}` as the source, be sure to use `Majic.Plug` to ensure its content_type and filename is correct."
  92   def store(upload, opts \\ []) do
  93     opts = get_opts(opts)
  94
  95     with {:ok, upload} <- prepare_upload(upload, opts),
  96          upload = %__MODULE__{upload | path: upload.path || "#{upload.id}/#{upload.name}"},
  97          {:ok, upload} <- Pleroma.Upload.Filter.filter(opts.filters, upload),
  98          description = get_description(upload),
  99          {_, true} <-
 100            {:description_limit,
 101             String.length(description) <= Pleroma.Config.get([:instance, :description_limit])},
 102          {:ok, url_spec} <- Pleroma.Uploaders.Uploader.put_file(opts.uploader, upload) do
 103       {:ok,
 104        %{
 105          "id" => Utils.generate_object_id(),
 106          "type" => opts.activity_type,
 107          "mediaType" => upload.content_type,
 108          "url" => [
 109            %{
 110              "type" => "Link",
 111              "mediaType" => upload.content_type,
 112              "href" => url_from_spec(upload, opts.base_url, url_spec)
 113            }
 114            |> Maps.put_if_present("width", upload.width)
 115            |> Maps.put_if_present("height", upload.height)
 116          ],
 117          "name" => description
 118        }
 119        |> Maps.put_if_present("blurhash", upload.blurhash)}
 120     else
 121       {:description_limit, _} ->
 122         {:error, :description_too_long}
 123
 124       {:error, error} ->
 125         Logger.error(
 126           "#{__MODULE__} store (using #{inspect(opts.uploader)}) failed: #{inspect(error)}"
 127         )
 128
 129         {:error, error}
 130     end
 131   end
 132
 133   def char_unescaped?(char) do
 134     URI.char_unreserved?(char) or char == ?/
 135   end
 136
 137   defp get_opts(opts) do
 138     {size_limit, activity_type} =
 139       case Keyword.get(opts, :type) do
 140         :banner ->
 141           {Pleroma.Config.get!([:instance, :banner_upload_limit]), "Image"}
 142
 143         :avatar ->
 144           {Pleroma.Config.get!([:instance, :avatar_upload_limit]), "Image"}
 145
 146         :background ->
 147           {Pleroma.Config.get!([:instance, :background_upload_limit]), "Image"}
 148
 149         _ ->
 150           {Pleroma.Config.get!([:instance, :upload_limit]), "Document"}
 151       end
 152
 153     %{
 154       activity_type: Keyword.get(opts, :activity_type, activity_type),
 155       size_limit: Keyword.get(opts, :size_limit, size_limit),
 156       uploader: Keyword.get(opts, :uploader, Pleroma.Config.get([__MODULE__, :uploader])),
 157       filters: Keyword.get(opts, :filters, Pleroma.Config.get([__MODULE__, :filters])),
 158       description: Keyword.get(opts, :description),
 159       base_url: base_url()
 160     }
 161   end
 162
 163   defp prepare_upload(%Plug.Upload{} = file, opts) do
 164     with :ok <- check_file_size(file.path, opts.size_limit) do
 165       {:ok,
 166        %__MODULE__{
 167          id: UUID.generate(),
 168          name: file.filename,
 169          tempfile: file.path,
 170          content_type: file.content_type,
 171          description: opts.description
 172        }}
 173     end
 174   end
 175
 176   defp prepare_upload(%{img: "data:image/" <> image_data}, opts) do
 177     parsed = Regex.named_captures(~r/(?<filetype>jpeg|png|gif);base64,(?<data>.*)/, image_data)
 178     data = Base.decode64!(parsed["data"], ignore: :whitespace)
 179     hash = Base.encode16(:crypto.hash(:sha256, data), case: :upper)
 180
 181     with :ok <- check_binary_size(data, opts.size_limit),
 182          tmp_path <- tempfile_for_image(data),
 183          {:ok, %{mime_type: content_type}} <-
 184            Majic.perform({:bytes, data}, pool: Pleroma.MajicPool),
 185          [ext | _] <- MIME.extensions(content_type) do
 186       {:ok,
 187        %__MODULE__{
 188          id: UUID.generate(),
 189          name: hash <> "." <> ext,
 190          tempfile: tmp_path,
 191          content_type: content_type,
 192          description: opts.description
 193        }}
 194     end
 195   end
 196
 197   # For Mix.Tasks.MigrateLocalUploads
 198   defp prepare_upload(%__MODULE__{tempfile: path} = upload, _opts) do
 199     with {:ok, %{mime_type: content_type}} <- Majic.perform(path, pool: Pleroma.MajicPool) do
 200       {:ok, %__MODULE__{upload | content_type: content_type}}
 201     end
 202   end
 203
 204   defp check_binary_size(binary, size_limit)
 205        when is_integer(size_limit) and size_limit > 0 and byte_size(binary) >= size_limit do
 206     {:error, :file_too_large}
 207   end
 208
 209   defp check_binary_size(_, _), do: :ok
 210
 211   defp check_file_size(path, size_limit) when is_integer(size_limit) and size_limit > 0 do
 212     with {:ok, %{size: size}} <- File.stat(path),
 213          true <- size <= size_limit do
 214       :ok
 215     else
 216       false -> {:error, :file_too_large}
 217       error -> error
 218     end
 219   end
 220
 221   defp check_file_size(_, _), do: :ok
 222
 223   # Creates a tempfile using the Plug.Upload Genserver which cleans them up
 224   # automatically.
 225   defp tempfile_for_image(data) do
 226     {:ok, tmp_path} = Plug.Upload.random_file("profile_pics")
 227     {:ok, tmp_file} = File.open(tmp_path, [:write, :raw, :binary])
 228     IO.binwrite(tmp_file, data)
 229
 230     tmp_path
 231   end
 232
 233   defp url_from_spec(%__MODULE__{name: name}, base_url, {:file, path}) do
 234     path =
 235       URI.encode(path, &char_unescaped?/1) <>
 236         if Pleroma.Config.get([__MODULE__, :link_name], false) do
 237           "?name=#{URI.encode(name, &char_unescaped?/1)}"
 238         else
 239           ""
 240         end
 241
 242     [base_url, path]
 243     |> Path.join()
 244   end
 245
 246   defp url_from_spec(_upload, _base_url, {:url, url}), do: url
 247
 248   def base_url do
 249     uploader = @config_impl.get([Pleroma.Upload, :uploader])
 250     upload_base_url = @config_impl.get([Pleroma.Upload, :base_url])
 251     public_endpoint = @config_impl.get([uploader, :public_endpoint])
 252
 253     case uploader do
 254       Pleroma.Uploaders.Local ->
 255         upload_base_url || Pleroma.Web.Endpoint.url() <> "/media/"
 256
 257       Pleroma.Uploaders.S3 ->
 258         bucket = @config_impl.get([Pleroma.Uploaders.S3, :bucket])
 259         truncated_namespace = @config_impl.get([Pleroma.Uploaders.S3, :truncated_namespace])
 260         namespace = @config_impl.get([Pleroma.Uploaders.S3, :bucket_namespace])
 261
 262         bucket_with_namespace =
 263           cond do
 264             !is_nil(truncated_namespace) ->
 265               truncated_namespace
 266
 267             !is_nil(namespace) ->
 268               namespace <> ":" <> bucket
 269
 270             true ->
 271               bucket
 272           end
 273
 274         if public_endpoint do
 275           Path.join([public_endpoint, bucket_with_namespace])
 276         else
 277           Path.join([upload_base_url, bucket_with_namespace])
 278         end
 279
 280       _ ->
 281         public_endpoint || upload_base_url || Pleroma.Web.Endpoint.url() <> "/media/"
 282     end
 283   end
 284 end