Git of dcc - anni/blob - lib/pleroma/web/mastodon_api/controllers/poll_controller.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2022 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MastodonAPI.PollController do
   6   use Pleroma.Web, :controller
   7
   8   import Pleroma.Web.ControllerHelper, only: [try_render: 3, json_response: 3]
   9
  10   alias Pleroma.Activity
  11   alias Pleroma.Object
  12   alias Pleroma.Web.ActivityPub.Visibility
  13   alias Pleroma.Web.CommonAPI
  14   alias Pleroma.Web.Plugs.OAuthScopesPlug
  15
  16   action_fallback(Pleroma.Web.MastodonAPI.FallbackController)
  17
  18   plug(Pleroma.Web.ApiSpec.CastAndValidate, replace_params: false)
  19
  20   plug(
  21     OAuthScopesPlug,
  22     %{scopes: ["read:statuses"], fallback: :proceed_unauthenticated} when action == :show
  23   )
  24
  25   plug(OAuthScopesPlug, %{scopes: ["write:statuses"]} when action == :vote)
  26
  27   defdelegate open_api_operation(action), to: Pleroma.Web.ApiSpec.PollOperation
  28
  29   @cachex Pleroma.Config.get([:cachex, :provider], Cachex)
  30
  31   @doc "GET /api/v1/polls/:id"
  32   def show(%{assigns: %{user: user}, private: %{open_api_spex: %{params: %{id: id}}}} = conn, _) do
  33     with %Object{} = object <- Object.get_by_id_and_maybe_refetch(id, interval: 60),
  34          %Activity{} = activity <- Activity.get_create_by_object_ap_id(object.data["id"]),
  35          true <- Visibility.visible_for_user?(activity, user) do
  36       try_render(conn, "show.json", %{object: object, for: user})
  37     else
  38       error when is_nil(error) or error == false ->
  39         render_error(conn, :not_found, "Record not found")
  40     end
  41   end
  42
  43   @doc "POST /api/v1/polls/:id/votes"
  44   def vote(
  45         %{
  46           assigns: %{user: user},
  47           private: %{open_api_spex: %{body_params: %{choices: choices}, params: %{id: id}}}
  48         } = conn,
  49         _
  50       ) do
  51     with %Object{data: %{"type" => "Question"}} = object <- Object.get_by_id(id),
  52          %Activity{} = activity <- Activity.get_create_by_object_ap_id(object.data["id"]),
  53          true <- Visibility.visible_for_user?(activity, user),
  54          {:ok, _activities, object} <- get_cached_vote_or_vote(user, object, choices) do
  55       try_render(conn, "show.json", %{object: object, for: user})
  56     else
  57       nil -> render_error(conn, :not_found, "Record not found")
  58       false -> render_error(conn, :not_found, "Record not found")
  59       {:error, message} -> json_response(conn, :unprocessable_entity, %{error: message})
  60     end
  61   end
  62
  63   defp get_cached_vote_or_vote(user, object, choices) do
  64     idempotency_key = "polls:#{user.id}:#{object.data["id"]}"
  65
  66     @cachex.fetch!(:idempotency_cache, idempotency_key, fn _ ->
  67       case CommonAPI.vote(user, object, choices) do
  68         {:error, _message} = res -> {:ignore, res}
  69         res -> {:commit, res}
  70       end
  71     end)
  72   end
  73 end