Git of dcc - anni/blob - lib/pleroma/web/o_auth/token.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2022 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.OAuth.Token do
   6   use Ecto.Schema
   7
   8   import Ecto.Changeset
   9
  10   alias Pleroma.Repo
  11   alias Pleroma.User
  12   alias Pleroma.Web.OAuth.App
  13   alias Pleroma.Web.OAuth.Authorization
  14   alias Pleroma.Web.OAuth.Token
  15   alias Pleroma.Web.OAuth.Token.Query
  16
  17   @type t :: %__MODULE__{}
  18
  19   schema "oauth_tokens" do
  20     field(:token, :string)
  21     field(:refresh_token, :string)
  22     field(:scopes, {:array, :string}, default: [])
  23     field(:valid_until, :naive_datetime_usec)
  24     belongs_to(:user, User, type: FlakeId.Ecto.CompatType)
  25     belongs_to(:app, App)
  26
  27     timestamps()
  28   end
  29
  30   def lifespan do
  31     Pleroma.Config.get!([:oauth2, :token_expires_in])
  32   end
  33
  34   @doc "Gets token by unique access token"
  35   @spec get_by_token(String.t()) :: {:ok, t()} | {:error, :not_found}
  36   def get_by_token(token) do
  37     token
  38     |> Query.get_by_token()
  39     |> Repo.find_resource()
  40   end
  41
  42   @doc "Gets token for app by access token"
  43   @spec get_by_token(App.t(), String.t()) :: {:ok, t()} | {:error, :not_found}
  44   def get_by_token(%App{id: app_id} = _app, token) do
  45     Query.get_by_app(app_id)
  46     |> Query.get_by_token(token)
  47     |> Repo.find_resource()
  48   end
  49
  50   @doc "Gets token for app by refresh token"
  51   @spec get_by_refresh_token(App.t(), String.t()) :: {:ok, t()} | {:error, :not_found}
  52   def get_by_refresh_token(%App{id: app_id} = _app, token) do
  53     Query.get_by_app(app_id)
  54     |> Query.get_by_refresh_token(token)
  55     |> Query.preload([:user])
  56     |> Repo.find_resource()
  57   end
  58
  59   @spec exchange_token(App.t(), Authorization.t()) ::
  60           {:ok, Token.t()} | {:error, Ecto.Changeset.t()}
  61   def exchange_token(app, auth) do
  62     with {:ok, auth} <- Authorization.use_token(auth),
  63          true <- auth.app_id == app.id do
  64       user = if auth.user_id, do: User.get_cached_by_id(auth.user_id), else: %User{}
  65
  66       create(
  67         app,
  68         user,
  69         %{scopes: auth.scopes}
  70       )
  71     end
  72   end
  73
  74   defp put_token(changeset) do
  75     changeset
  76     |> change(%{token: Token.Utils.generate_token()})
  77     |> validate_required([:token])
  78     |> unique_constraint(:token)
  79   end
  80
  81   defp put_refresh_token(changeset, attrs) do
  82     refresh_token = Map.get(attrs, :refresh_token, Token.Utils.generate_token())
  83
  84     changeset
  85     |> change(%{refresh_token: refresh_token})
  86     |> validate_required([:refresh_token])
  87     |> unique_constraint(:refresh_token)
  88   end
  89
  90   defp put_valid_until(changeset, attrs) do
  91     valid_until =
  92       Map.get(attrs, :valid_until, NaiveDateTime.add(NaiveDateTime.utc_now(), lifespan()))
  93
  94     changeset
  95     |> change(%{valid_until: valid_until})
  96     |> validate_required([:valid_until])
  97   end
  98
  99   @spec create(App.t(), User.t(), map()) :: {:ok, Token} | {:error, Ecto.Changeset.t()}
 100   def create(%App{} = app, %User{} = user, attrs \\ %{}) do
 101     with {:ok, token} <- do_create(app, user, attrs) do
 102       if Pleroma.Config.get([:oauth2, :clean_expired_tokens]) do
 103         Pleroma.Workers.PurgeExpiredToken.enqueue(%{
 104           token_id: token.id,
 105           valid_until: DateTime.from_naive!(token.valid_until, "Etc/UTC"),
 106           mod: __MODULE__
 107         })
 108       end
 109
 110       {:ok, token}
 111     end
 112   end
 113
 114   defp do_create(app, user, attrs) do
 115     %__MODULE__{user_id: user.id, app_id: app.id}
 116     |> cast(%{scopes: attrs[:scopes] || app.scopes}, [:scopes])
 117     |> validate_required([:scopes, :app_id])
 118     |> put_valid_until(attrs)
 119     |> put_token()
 120     |> put_refresh_token(attrs)
 121     |> Repo.insert()
 122   end
 123
 124   def delete_user_tokens(%User{id: user_id}) do
 125     Query.get_by_user(user_id)
 126     |> Repo.delete_all()
 127   end
 128
 129   def delete_user_token(%User{id: user_id}, token_id) do
 130     Query.get_by_user(user_id)
 131     |> Query.get_by_id(token_id)
 132     |> Repo.delete_all()
 133   end
 134
 135   def get_user_tokens(%User{id: user_id}) do
 136     Query.get_by_user(user_id)
 137     |> Query.preload([:app])
 138     |> Repo.all()
 139   end
 140
 141   def expired?(%__MODULE__{valid_until: valid_until}) do
 142     NaiveDateTime.diff(NaiveDateTime.utc_now(), valid_until) > 0
 143   end
 144
 145   def expired?(_), do: false
 146 end