Git of dcc - anni/blob - lib/pleroma/web/rich_media/parser/ttl/aws_signed_url.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2022 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.RichMedia.Parser.TTL.AwsSignedUrl do
   6   @behaviour Pleroma.Web.RichMedia.Parser.TTL
   7
   8   @impl true
   9   def ttl(data, _url) do
  10     image = Map.get(data, "image")
  11
  12     if aws_signed_url?(image) do
  13       image
  14       |> parse_query_params()
  15       |> format_query_params()
  16       |> get_expiration_timestamp()
  17     else
  18       nil
  19     end
  20   end
  21
  22   defp aws_signed_url?(image) when is_binary(image) and image != "" do
  23     %URI{host: host, query: query} = URI.parse(image)
  24
  25     is_binary(host) and String.contains?(host, "amazonaws.com") and
  26       String.contains?(query, "X-Amz-Expires")
  27   end
  28
  29   defp aws_signed_url?(_), do: nil
  30
  31   defp parse_query_params(image) do
  32     %URI{query: query} = URI.parse(image)
  33     query
  34   end
  35
  36   defp format_query_params(query) do
  37     query
  38     |> String.split(~r/&|=/)
  39     |> Enum.chunk_every(2)
  40     |> Map.new(fn [k, v] -> {k, v} end)
  41   end
  42
  43   defp get_expiration_timestamp(params) when is_map(params) do
  44     {:ok, date} =
  45       params
  46       |> Map.get("X-Amz-Date")
  47       |> Timex.parse("{ISO:Basic:Z}")
  48
  49     Timex.to_unix(date) + String.to_integer(Map.get(params, "X-Amz-Expires"))
  50   end
  51 end