Git of dcc - anni/blob - test/pleroma/web/activity_pub/views/user_view_test.exs

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2022 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.UserViewTest do
   6   use Pleroma.DataCase, async: true
   7   import Pleroma.Factory
   8
   9   alias Pleroma.User
  10   alias Pleroma.Web.ActivityPub.UserView
  11   alias Pleroma.Web.CommonAPI
  12
  13   test "Renders a user, including the public key" do
  14     user = insert(:user)
  15
  16     result = UserView.render("user.json", %{user: user})
  17
  18     assert result["id"] == user.ap_id
  19     assert result["preferredUsername"] == user.nickname
  20
  21     assert String.contains?(result["publicKey"]["publicKeyPem"], "BEGIN PUBLIC KEY")
  22   end
  23
  24   test "Renders profile fields" do
  25     fields = [
  26       %{"name" => "foo", "value" => "bar"}
  27     ]
  28
  29     {:ok, user} =
  30       insert(:user)
  31       |> User.update_changeset(%{fields: fields})
  32       |> User.update_and_set_cache()
  33
  34     assert %{
  35              "attachment" => [%{"name" => "foo", "type" => "PropertyValue", "value" => "bar"}]
  36            } = UserView.render("user.json", %{user: user})
  37   end
  38
  39   test "Renders with emoji tags" do
  40     user = insert(:user, emoji: %{"bib" => "/test"})
  41
  42     assert %{
  43              "tag" => [
  44                %{
  45                  "icon" => %{"type" => "Image", "url" => "/test"},
  46                  "id" => "/test",
  47                  "name" => ":bib:",
  48                  "type" => "Emoji",
  49                  "updated" => "1970-01-01T00:00:00Z"
  50                }
  51              ]
  52            } = UserView.render("user.json", %{user: user})
  53   end
  54
  55   test "Does not add an avatar image if the user hasn't set one" do
  56     user = insert(:user)
  57
  58     result = UserView.render("user.json", %{user: user})
  59     refute result["icon"]
  60     refute result["image"]
  61
  62     user =
  63       insert(:user,
  64         avatar: %{"url" => [%{"href" => "https://someurl"}]},
  65         banner: %{"url" => [%{"href" => "https://somebanner"}]}
  66       )
  67
  68     result = UserView.render("user.json", %{user: user})
  69     assert result["icon"]["url"] == "https://someurl"
  70     assert result["image"]["url"] == "https://somebanner"
  71   end
  72
  73   test "renders an invisible user with the invisible property set to true" do
  74     user = insert(:user, invisible: true)
  75
  76     assert %{"invisible" => true} = UserView.render("service.json", %{user: user})
  77   end
  78
  79   test "service has a few essential fields" do
  80     user = insert(:user)
  81     result = UserView.render("service.json", %{user: user})
  82     assert result["id"]
  83     assert result["type"] == "Application"
  84     assert result["inbox"]
  85     assert result["outbox"]
  86   end
  87
  88   test "renders AKAs" do
  89     akas = ["https://i.tusooa.xyz/users/test-pleroma"]
  90     user = insert(:user, also_known_as: akas)
  91     assert %{"alsoKnownAs" => ^akas} = UserView.render("user.json", %{user: user})
  92   end
  93
  94   test "renders full nickname" do
  95     clear_config([Pleroma.Web.WebFinger, :domain], "plemora.dev")
  96
  97     user = insert(:user, nickname: "user")
  98     assert %{"webfinger" => "acct:user@plemora.dev"} = UserView.render("user.json", %{user: user})
  99   end
 100
 101   describe "endpoints" do
 102     test "local users have a usable endpoints structure" do
 103       user = insert(:user)
 104
 105       result = UserView.render("user.json", %{user: user})
 106
 107       assert result["id"] == user.ap_id
 108
 109       %{
 110         "sharedInbox" => _,
 111         "oauthAuthorizationEndpoint" => _,
 112         "oauthRegistrationEndpoint" => _,
 113         "oauthTokenEndpoint" => _
 114       } = result["endpoints"]
 115     end
 116
 117     test "remote users have an empty endpoints structure" do
 118       user = insert(:user, local: false)
 119
 120       result = UserView.render("user.json", %{user: user})
 121
 122       assert result["id"] == user.ap_id
 123       assert result["endpoints"] == %{}
 124     end
 125
 126     test "instance users do not expose oAuth endpoints" do
 127       user = insert(:user, nickname: nil, local: true)
 128
 129       result = UserView.render("user.json", %{user: user})
 130
 131       refute result["endpoints"]["oauthAuthorizationEndpoint"]
 132       refute result["endpoints"]["oauthRegistrationEndpoint"]
 133       refute result["endpoints"]["oauthTokenEndpoint"]
 134     end
 135   end
 136
 137   describe "followers" do
 138     test "sets totalItems to zero when followers are hidden" do
 139       user = insert(:user)
 140       other_user = insert(:user)
 141       {:ok, _other_user, user, _activity} = CommonAPI.follow(other_user, user)
 142       assert %{"totalItems" => 1} = UserView.render("followers.json", %{user: user})
 143       user = Map.merge(user, %{hide_followers_count: true, hide_followers: true})
 144       refute UserView.render("followers.json", %{user: user}) |> Map.has_key?("totalItems")
 145     end
 146
 147     test "sets correct totalItems when followers are hidden but the follower counter is not" do
 148       user = insert(:user)
 149       other_user = insert(:user)
 150       {:ok, _other_user, user, _activity} = CommonAPI.follow(other_user, user)
 151       assert %{"totalItems" => 1} = UserView.render("followers.json", %{user: user})
 152       user = Map.merge(user, %{hide_followers_count: false, hide_followers: true})
 153       assert %{"totalItems" => 1} = UserView.render("followers.json", %{user: user})
 154     end
 155   end
 156
 157   describe "following" do
 158     test "sets totalItems to zero when follows are hidden" do
 159       user = insert(:user)
 160       other_user = insert(:user)
 161       {:ok, user, _other_user, _activity} = CommonAPI.follow(user, other_user)
 162       assert %{"totalItems" => 1} = UserView.render("following.json", %{user: user})
 163       user = Map.merge(user, %{hide_follows_count: true, hide_follows: true})
 164       assert %{"totalItems" => 0} = UserView.render("following.json", %{user: user})
 165     end
 166
 167     test "sets correct totalItems when follows are hidden but the follow counter is not" do
 168       user = insert(:user)
 169       other_user = insert(:user)
 170       {:ok, user, _other_user, _activity} = CommonAPI.follow(user, other_user)
 171       assert %{"totalItems" => 1} = UserView.render("following.json", %{user: user})
 172       user = Map.merge(user, %{hide_follows_count: false, hide_follows: true})
 173       assert %{"totalItems" => 1} = UserView.render("following.json", %{user: user})
 174     end
 175   end
 176
 177   describe "acceptsChatMessages" do
 178     test "it returns this value if it is set" do
 179       true_user = insert(:user, accepts_chat_messages: true)
 180       false_user = insert(:user, accepts_chat_messages: false)
 181       nil_user = insert(:user, accepts_chat_messages: nil)
 182
 183       assert %{"capabilities" => %{"acceptsChatMessages" => true}} =
 184                UserView.render("user.json", user: true_user)
 185
 186       assert %{"capabilities" => %{"acceptsChatMessages" => false}} =
 187                UserView.render("user.json", user: false_user)
 188
 189       refute Map.has_key?(
 190                UserView.render("user.json", user: nil_user)["capabilities"],
 191                "acceptsChatMessages"
 192              )
 193     end
 194   end
 195 end