Git of dcc - anni/blob - lib/mix/tasks/pleroma/relay.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2022 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Mix.Tasks.Pleroma.Relay do
   6   use Mix.Task
   7   import Mix.Pleroma
   8   alias Pleroma.Web.ActivityPub.Relay
   9
  10   @shortdoc "Manages remote relays"
  11   @moduledoc File.read!("docs/administration/CLI_tasks/relay.md")
  12
  13   def run(["follow", target]) do
  14     start_pleroma()
  15
  16     with {:ok, _activity} <- Relay.follow(target) do
  17       # put this task to sleep to allow the genserver to push out the messages
  18       :timer.sleep(500)
  19     else
  20       {:error, e} -> shell_error("Error while following #{target}: #{inspect(e)}")
  21     end
  22   end
  23
  24   def run(["unfollow", target | rest]) do
  25     start_pleroma()
  26
  27     {options, [], []} =
  28       OptionParser.parse(
  29         rest,
  30         strict: [force: :boolean],
  31         aliases: [f: :force]
  32       )
  33
  34     force = Keyword.get(options, :force, false)
  35
  36     with {:ok, _activity} <- Relay.unfollow(target, %{force: force}) do
  37       # put this task to sleep to allow the genserver to push out the messages
  38       :timer.sleep(500)
  39     else
  40       {:error, e} -> shell_error("Error while following #{target}: #{inspect(e)}")
  41     end
  42   end
  43
  44   def run(["list"]) do
  45     start_pleroma()
  46
  47     with {:ok, list} <- Relay.list() do
  48       Enum.each(list, &print_relay_url/1)
  49     else
  50       {:error, e} -> shell_error("Error while fetching relay subscription list: #{inspect(e)}")
  51     end
  52   end
  53
  54   defp print_relay_url(%{followed_back: false} = relay) do
  55     shell_info("#{relay.actor} - no Accept received (relay didn't follow back)")
  56   end
  57
  58   defp print_relay_url(relay), do: shell_info(relay.actor)
  59 end