Git of dcc - anni/blob - lib/pleroma/emoji.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2022 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Emoji do
   6   @moduledoc """
   7   This GenServer stores in an ETS table the list of the loaded emojis,
   8   and also allows to reload the list at runtime.
   9   """
  10   use GenServer
  11
  12   alias Pleroma.Emoji.Combinations
  13   alias Pleroma.Emoji.Loader
  14
  15   require Logger
  16
  17   @ets __MODULE__.Ets
  18   @ets_options [
  19     :ordered_set,
  20     :protected,
  21     :named_table,
  22     {:read_concurrency, true}
  23   ]
  24
  25   defstruct [:code, :file, :tags, :safe_code, :safe_file]
  26
  27   @doc "Build emoji struct"
  28   def build({code, file, tags}) do
  29     %__MODULE__{
  30       code: code,
  31       file: file,
  32       tags: tags,
  33       safe_code: Pleroma.HTML.strip_tags(code),
  34       safe_file: Pleroma.HTML.strip_tags(file)
  35     }
  36   end
  37
  38   def build({code, file}), do: build({code, file, []})
  39
  40   @doc false
  41   def start_link(_) do
  42     GenServer.start_link(__MODULE__, [], name: __MODULE__)
  43   end
  44
  45   @doc "Reloads the emojis from disk."
  46   @spec reload() :: :ok
  47   def reload do
  48     GenServer.call(__MODULE__, :reload)
  49   end
  50
  51   @doc "Returns the path of the emoji `name`."
  52   @spec get(String.t()) :: String.t() | nil
  53   def get(name) do
  54     case :ets.lookup(@ets, name) do
  55       [{_, path}] -> path
  56       _ -> nil
  57     end
  58   end
  59
  60   @spec exist?(String.t()) :: boolean()
  61   def exist?(name), do: not is_nil(get(name))
  62
  63   @doc "Returns all the emojos!!"
  64   @spec get_all() :: list({String.t(), String.t(), String.t()})
  65   def get_all do
  66     :ets.tab2list(@ets)
  67   end
  68
  69   @doc "Clear out old emojis"
  70   def clear_all, do: :ets.delete_all_objects(@ets)
  71
  72   @doc false
  73   def init(_) do
  74     @ets = :ets.new(@ets, @ets_options)
  75     GenServer.cast(self(), :reload)
  76     {:ok, nil}
  77   end
  78
  79   @doc false
  80   def handle_cast(:reload, state) do
  81     update_emojis(Loader.load())
  82     {:noreply, state}
  83   end
  84
  85   @doc false
  86   def handle_call(:reload, _from, state) do
  87     update_emojis(Loader.load())
  88     {:reply, :ok, state}
  89   end
  90
  91   @doc false
  92   def terminate(_, _) do
  93     :ok
  94   end
  95
  96   @doc false
  97   def code_change(_old_vsn, state, _extra) do
  98     update_emojis(Loader.load())
  99     {:ok, state}
 100   end
 101
 102   defp update_emojis(emojis) do
 103     :ets.insert(@ets, emojis)
 104   end
 105
 106   @external_resource "lib/pleroma/emoji-test.txt"
 107
 108   regional_indicators =
 109     Enum.map(127_462..127_487, fn codepoint ->
 110       <<codepoint::utf8>>
 111     end)
 112
 113   emojis =
 114     @external_resource
 115     |> File.read!()
 116     |> String.split("\n")
 117     |> Enum.filter(fn line ->
 118       line != "" and not String.starts_with?(line, "#") and
 119         String.contains?(line, "fully-qualified")
 120     end)
 121     |> Enum.map(fn line ->
 122       line
 123       |> String.split(";", parts: 2)
 124       |> hd()
 125       |> String.trim()
 126       |> String.split()
 127       |> Enum.map(fn codepoint ->
 128         <<String.to_integer(codepoint, 16)::utf8>>
 129       end)
 130       |> Enum.join()
 131     end)
 132     |> Enum.uniq()
 133
 134   emojis = emojis ++ regional_indicators
 135
 136   for emoji <- emojis do
 137     def is_unicode_emoji?(unquote(emoji)), do: true
 138   end
 139
 140   def is_unicode_emoji?(_), do: false
 141
 142   emoji_qualification_map =
 143     emojis
 144     |> Enum.filter(&String.contains?(&1, "\uFE0F"))
 145     |> Combinations.variate_emoji_qualification()
 146
 147   for {qualified, unqualified_list} <- emoji_qualification_map do
 148     for unqualified <- unqualified_list do
 149       def fully_qualify_emoji(unquote(unqualified)), do: unquote(qualified)
 150     end
 151   end
 152
 153   def fully_qualify_emoji(emoji), do: emoji
 154 end