Git of dcc - anni/blob - lib/pleroma/web/activity_pub/object_validators/audio_video_validator.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2022 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.ObjectValidators.AudioVideoValidator do
   6   use Ecto.Schema
   7
   8   alias Pleroma.Web.ActivityPub.ObjectValidators.CommonFixes
   9   alias Pleroma.Web.ActivityPub.ObjectValidators.CommonValidations
  10   alias Pleroma.Web.ActivityPub.Transmogrifier
  11
  12   import Ecto.Changeset
  13
  14   @primary_key false
  15   @derive Jason.Encoder
  16
  17   embedded_schema do
  18     quote do
  19       unquote do
  20         import Elixir.Pleroma.Web.ActivityPub.ObjectValidators.CommonFields
  21         message_fields()
  22         object_fields()
  23         status_object_fields()
  24       end
  25     end
  26   end
  27
  28   def cast_and_apply(data) do
  29     data
  30     |> cast_data
  31     |> apply_action(:insert)
  32   end
  33
  34   def cast_and_validate(data) do
  35     data
  36     |> cast_data()
  37     |> validate_data()
  38   end
  39
  40   def cast_data(data) do
  41     %__MODULE__{}
  42     |> changeset(data)
  43   end
  44
  45   defp find_attachment(url) do
  46     mpeg_url =
  47       Enum.find(url, fn
  48         %{"mediaType" => mime_type, "tag" => tags} when is_list(tags) ->
  49           mime_type == "application/x-mpegURL"
  50
  51         _ ->
  52           false
  53       end)
  54
  55     url
  56     |> Enum.concat(mpeg_url["tag"] || [])
  57     |> Enum.find(fn
  58       %{"mediaType" => mime_type} -> String.starts_with?(mime_type, ["video/", "audio/"])
  59       %{"mimeType" => mime_type} -> String.starts_with?(mime_type, ["video/", "audio/"])
  60       _ -> false
  61     end)
  62   end
  63
  64   defp fix_url(%{"url" => url} = data) when is_list(url) do
  65     attachment = find_attachment(url)
  66
  67     link_element =
  68       Enum.find(url, fn
  69         %{"mediaType" => "text/html"} -> true
  70         %{"mimeType" => "text/html"} -> true
  71         _ -> false
  72       end)
  73
  74     data
  75     |> Map.put("attachment", [attachment])
  76     |> Map.put("url", link_element["href"])
  77   end
  78
  79   defp fix_url(data), do: data
  80
  81   defp fix_content(%{"mediaType" => "text/markdown", "content" => content} = data)
  82        when is_binary(content) do
  83     content =
  84       content
  85       |> Pleroma.Formatter.markdown_to_html()
  86       |> Pleroma.HTML.filter_tags()
  87
  88     Map.put(data, "content", content)
  89   end
  90
  91   defp fix_content(data), do: data
  92
  93   defp fix(data) do
  94     data
  95     |> CommonFixes.fix_actor()
  96     |> CommonFixes.fix_object_defaults()
  97     |> Transmogrifier.fix_emoji()
  98     |> fix_url()
  99     |> fix_content()
 100   end
 101
 102   def changeset(struct, data) do
 103     data = fix(data)
 104
 105     struct
 106     |> cast(data, __schema__(:fields) -- [:attachment, :tag])
 107     |> cast_embed(:attachment, required: true)
 108     |> cast_embed(:tag)
 109   end
 110
 111   defp validate_data(data_cng) do
 112     data_cng
 113     |> validate_inclusion(:type, ["Audio", "Video"])
 114     |> validate_required([:id, :actor, :attributedTo, :type, :context])
 115     |> CommonValidations.validate_any_presence([:cc, :to])
 116     |> CommonValidations.validate_fields_match([:actor, :attributedTo])
 117     |> CommonValidations.validate_actor_presence()
 118     |> CommonValidations.validate_host_match()
 119   end
 120 end