Git of dcc - anni/blob - lib/pleroma/web/activity_pub/object_validators/chat_message_validator.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2022 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.ObjectValidators.ChatMessageValidator do
   6   use Ecto.Schema
   7
   8   alias Pleroma.EctoType.ActivityPub.ObjectValidators
   9   alias Pleroma.User
  10   alias Pleroma.Web.ActivityPub.ObjectValidators.AttachmentValidator
  11
  12   import Ecto.Changeset
  13   import Pleroma.Web.ActivityPub.Transmogrifier, only: [fix_emoji: 1]
  14
  15   @primary_key false
  16   @derive Jason.Encoder
  17
  18   embedded_schema do
  19     field(:id, ObjectValidators.ObjectID, primary_key: true)
  20     field(:to, ObjectValidators.Recipients, default: [])
  21     field(:type, :string)
  22     field(:content, ObjectValidators.SafeText)
  23     field(:actor, ObjectValidators.ObjectID)
  24     field(:published, ObjectValidators.DateTime)
  25     field(:emoji, ObjectValidators.Emoji, default: %{})
  26
  27     embeds_one(:attachment, AttachmentValidator)
  28   end
  29
  30   def cast_and_apply(data) do
  31     data
  32     |> cast_data
  33     |> apply_action(:insert)
  34   end
  35
  36   def cast_and_validate(data) do
  37     data
  38     |> cast_data()
  39     |> validate_data()
  40   end
  41
  42   def cast_data(data) do
  43     %__MODULE__{}
  44     |> changeset(data)
  45   end
  46
  47   def fix(data) do
  48     data
  49     |> fix_emoji()
  50     |> fix_attachment()
  51     |> Map.put_new("actor", data["attributedTo"])
  52   end
  53
  54   # Throws everything but the first one away
  55   def fix_attachment(%{"attachment" => [attachment | _]} = data) do
  56     data
  57     |> Map.put("attachment", attachment)
  58   end
  59
  60   def fix_attachment(data), do: data
  61
  62   def changeset(struct, data) do
  63     data = fix(data)
  64
  65     struct
  66     |> cast(data, List.delete(__schema__(:fields), :attachment))
  67     |> cast_embed(:attachment)
  68   end
  69
  70   defp validate_data(data_cng) do
  71     data_cng
  72     |> validate_inclusion(:type, ["ChatMessage"])
  73     |> validate_required([:id, :actor, :to, :type, :published])
  74     |> validate_content_or_attachment()
  75     |> validate_length(:to, is: 1)
  76     |> validate_length(:content, max: Pleroma.Config.get([:instance, :remote_limit]))
  77     |> validate_local_concern()
  78   end
  79
  80   def validate_content_or_attachment(cng) do
  81     attachment = get_field(cng, :attachment)
  82
  83     if attachment do
  84       cng
  85     else
  86       cng
  87       |> validate_required([:content])
  88     end
  89   end
  90
  91   @doc """
  92   Validates the following
  93   - If both users are in our system
  94   - If at least one of the users in this ChatMessage is a local user
  95   - If the recipient is not blocking the actor
  96   - If the recipient is explicitly not accepting chat messages
  97   """
  98   def validate_local_concern(cng) do
  99     with actor_ap <- get_field(cng, :actor),
 100          {_, %User{} = actor} <- {:find_actor, User.get_cached_by_ap_id(actor_ap)},
 101          {_, %User{} = recipient} <-
 102            {:find_recipient, User.get_cached_by_ap_id(get_field(cng, :to) |> hd())},
 103          {_, false} <- {:not_accepting_chats?, recipient.accepts_chat_messages == false},
 104          {_, false} <- {:blocking_actor?, User.blocks?(recipient, actor)},
 105          {_, true} <- {:local?, Enum.any?([actor, recipient], & &1.local)} do
 106       cng
 107     else
 108       {:blocking_actor?, true} ->
 109         cng
 110         |> add_error(:actor, "actor is blocked by recipient")
 111
 112       {:not_accepting_chats?, true} ->
 113         cng
 114         |> add_error(:to, "recipient does not accept chat messages")
 115
 116       {:local?, false} ->
 117         cng
 118         |> add_error(:actor, "actor and recipient are both remote")
 119
 120       {:find_actor, _} ->
 121         cng
 122         |> add_error(:actor, "can't find user")
 123
 124       {:find_recipient, _} ->
 125         cng
 126         |> add_error(:to, "can't find user")
 127     end
 128   end
 129 end