Git of dcc - anni/blob - lib/pleroma/web/activity_pub/object_validators/emoji_react_validator.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2022 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.ObjectValidators.EmojiReactValidator do
   6   use Ecto.Schema
   7
   8   alias Pleroma.Object
   9   alias Pleroma.Web.ActivityPub.ObjectValidators.CommonFixes
  10
  11   import Ecto.Changeset
  12   import Pleroma.Web.ActivityPub.ObjectValidators.CommonValidations
  13
  14   @primary_key false
  15
  16   embedded_schema do
  17     quote do
  18       unquote do
  19         import Elixir.Pleroma.Web.ActivityPub.ObjectValidators.CommonFields
  20         message_fields()
  21         activity_fields()
  22       end
  23     end
  24
  25     field(:context, :string)
  26     field(:content, :string)
  27   end
  28
  29   def cast_and_validate(data) do
  30     data
  31     |> cast_data()
  32     |> validate_data()
  33   end
  34
  35   def cast_data(data) do
  36     data =
  37       data
  38       |> fix()
  39
  40     %__MODULE__{}
  41     |> changeset(data)
  42   end
  43
  44   def changeset(struct, data) do
  45     struct
  46     |> cast(data, __schema__(:fields))
  47   end
  48
  49   defp fix(data) do
  50     data =
  51       data
  52       |> fix_emoji_qualification()
  53       |> CommonFixes.fix_actor()
  54       |> CommonFixes.fix_activity_addressing()
  55
  56     with %Object{} = object <- Object.normalize(data["object"]) do
  57       data
  58       |> CommonFixes.fix_activity_context(object)
  59       |> CommonFixes.fix_object_action_recipients(object)
  60     else
  61       _ -> data
  62     end
  63   end
  64
  65   defp fix_emoji_qualification(%{"content" => emoji} = data) do
  66     new_emoji = Pleroma.Emoji.fully_qualify_emoji(emoji)
  67
  68     cond do
  69       Pleroma.Emoji.is_unicode_emoji?(emoji) ->
  70         data
  71
  72       Pleroma.Emoji.is_unicode_emoji?(new_emoji) ->
  73         data |> Map.put("content", new_emoji)
  74
  75       true ->
  76         data
  77     end
  78   end
  79
  80   defp fix_emoji_qualification(data), do: data
  81
  82   defp validate_emoji(cng) do
  83     content = get_field(cng, :content)
  84
  85     if Pleroma.Emoji.is_unicode_emoji?(content) do
  86       cng
  87     else
  88       cng
  89       |> add_error(:content, "must be a single character emoji")
  90     end
  91   end
  92
  93   defp validate_data(data_cng) do
  94     data_cng
  95     |> validate_inclusion(:type, ["EmojiReact"])
  96     |> validate_required([:id, :type, :object, :actor, :context, :to, :cc, :content])
  97     |> validate_actor_presence()
  98     |> validate_object_presence()
  99     |> validate_emoji()
 100   end
 101 end