Git of dcc - anni/blob - lib/pleroma/web/admin_api/controllers/instance_document_controller.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2022 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.AdminAPI.InstanceDocumentController do
   6   use Pleroma.Web, :controller
   7
   8   alias Pleroma.Web.InstanceDocument
   9   alias Pleroma.Web.Plugs.InstanceStatic
  10   alias Pleroma.Web.Plugs.OAuthScopesPlug
  11
  12   plug(Pleroma.Web.ApiSpec.CastAndValidate)
  13
  14   action_fallback(Pleroma.Web.AdminAPI.FallbackController)
  15
  16   defdelegate open_api_operation(action), to: Pleroma.Web.ApiSpec.Admin.InstanceDocumentOperation
  17
  18   plug(OAuthScopesPlug, %{scopes: ["admin:read"]} when action == :show)
  19   plug(OAuthScopesPlug, %{scopes: ["admin:write"]} when action in [:update, :delete])
  20
  21   def show(conn, %{name: document_name}) do
  22     with {:ok, url} <- InstanceDocument.get(document_name),
  23          {:ok, content} <- File.read(InstanceStatic.file_path(url)) do
  24       conn
  25       |> put_resp_content_type("text/html")
  26       |> send_resp(200, content)
  27     end
  28   end
  29
  30   def update(%{body_params: %{file: file}} = conn, %{name: document_name}) do
  31     with {:ok, url} <- InstanceDocument.put(document_name, file.path) do
  32       json(conn, %{"url" => url})
  33     end
  34   end
  35
  36   def delete(conn, %{name: document_name}) do
  37     with :ok <- InstanceDocument.delete(document_name) do
  38       json(conn, %{})
  39     end
  40   end
  41 end