Git of dcc - anni/blob - lib/pleroma/web/admin_api/controllers/media_proxy_cache_controller.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2022 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.AdminAPI.MediaProxyCacheController do
   6   use Pleroma.Web, :controller
   7
   8   alias Pleroma.Web.ApiSpec.Admin, as: Spec
   9   alias Pleroma.Web.MediaProxy
  10   alias Pleroma.Web.Plugs.OAuthScopesPlug
  11
  12   @cachex Pleroma.Config.get([:cachex, :provider], Cachex)
  13
  14   plug(Pleroma.Web.ApiSpec.CastAndValidate)
  15
  16   plug(
  17     OAuthScopesPlug,
  18     %{scopes: ["admin:read:media_proxy_caches"]} when action in [:index]
  19   )
  20
  21   plug(
  22     OAuthScopesPlug,
  23     %{scopes: ["admin:write:media_proxy_caches"]} when action in [:purge, :delete]
  24   )
  25
  26   action_fallback(Pleroma.Web.AdminAPI.FallbackController)
  27
  28   defdelegate open_api_operation(action), to: Spec.MediaProxyCacheOperation
  29
  30   def index(%{assigns: %{user: _}} = conn, params) do
  31     entries = fetch_entries(params)
  32     urls = paginate_entries(entries, params.page, params.page_size)
  33
  34     render(conn, "index.json",
  35       urls: urls,
  36       page_size: params.page_size,
  37       count: length(entries)
  38     )
  39   end
  40
  41   defp fetch_entries(params) do
  42     MediaProxy.cache_table()
  43     |> @cachex.stream!(Cachex.Query.create(true, :key))
  44     |> filter_entries(params[:query])
  45   end
  46
  47   defp filter_entries(stream, query) when is_binary(query) do
  48     regex = ~r/#{query}/i
  49
  50     stream
  51     |> Enum.filter(fn url -> String.match?(url, regex) end)
  52     |> Enum.to_list()
  53   end
  54
  55   defp filter_entries(stream, _), do: Enum.to_list(stream)
  56
  57   defp paginate_entries(entries, page, page_size) do
  58     offset = page_size * (page - 1)
  59     Enum.slice(entries, offset, page_size)
  60   end
  61
  62   def delete(%{assigns: %{user: _}, body_params: %{urls: urls}} = conn, _) do
  63     MediaProxy.remove_from_banned_urls(urls)
  64     json(conn, %{})
  65   end
  66
  67   def purge(%{assigns: %{user: _}, body_params: %{urls: urls, ban: ban}} = conn, _) do
  68     MediaProxy.Invalidation.purge(urls)
  69
  70     if ban do
  71       MediaProxy.put_in_banned_urls(urls)
  72     end
  73
  74     json(conn, %{})
  75   end
  76 end