Git of dcc - anni/blob - lib/pleroma/web/feed/tag_controller.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2022 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.Feed.TagController do
   6   use Pleroma.Web, :controller
   7
   8   alias Pleroma.Config
   9   alias Pleroma.Web.ActivityPub.ActivityPub
  10   alias Pleroma.Web.Feed.FeedView
  11
  12   def feed(conn, params) do
  13     if Config.get!([:instance, :public]) do
  14       render_feed(conn, params)
  15     else
  16       render_error(conn, :not_found, "Not found")
  17     end
  18   end
  19
  20   defp render_feed(conn, %{"tag" => raw_tag} = params) do
  21     {format, tag} = parse_tag(raw_tag)
  22
  23     activities =
  24       %{type: ["Create"], tag: tag}
  25       |> Pleroma.Maps.put_if_present(:max_id, params["max_id"])
  26       |> ActivityPub.fetch_public_activities()
  27
  28     conn
  29     |> put_resp_content_type("application/#{format}+xml")
  30     |> put_view(FeedView)
  31     |> render("tag.#{format}",
  32       activities: activities,
  33       tag: tag,
  34       feed_config: Config.get([:feed])
  35     )
  36   end
  37
  38   @spec parse_tag(binary() | any()) :: {format :: String.t(), tag :: String.t()}
  39   defp parse_tag(raw_tag) do
  40     case is_binary(raw_tag) && Enum.reverse(String.split(raw_tag, ".")) do
  41       [format | tag] when format in ["rss", "atom"] ->
  42         {format, Enum.join(tag, ".")}
  43
  44       _ ->
  45         {"atom", raw_tag}
  46     end
  47   end
  48 end