Git of dcc - anni/blob - lib/pleroma/web/pleroma_api/controllers/emoji_reaction_controller.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2022 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.PleromaAPI.EmojiReactionController do
   6   use Pleroma.Web, :controller
   7
   8   alias Pleroma.Activity
   9   alias Pleroma.Object
  10   alias Pleroma.User
  11   alias Pleroma.Web.CommonAPI
  12   alias Pleroma.Web.MastodonAPI.StatusView
  13   alias Pleroma.Web.Plugs.OAuthScopesPlug
  14
  15   plug(Pleroma.Web.ApiSpec.CastAndValidate)
  16   plug(OAuthScopesPlug, %{scopes: ["write:statuses"]} when action in [:create, :delete])
  17
  18   plug(
  19     OAuthScopesPlug,
  20     %{scopes: ["read:statuses"], fallback: :proceed_unauthenticated}
  21     when action == :index
  22   )
  23
  24   defdelegate open_api_operation(action), to: Pleroma.Web.ApiSpec.EmojiReactionOperation
  25
  26   action_fallback(Pleroma.Web.MastodonAPI.FallbackController)
  27
  28   def index(%{assigns: %{user: user}} = conn, %{id: activity_id} = params) do
  29     with true <- Pleroma.Config.get([:instance, :show_reactions]),
  30          %Activity{} = activity <- Activity.get_by_id_with_object(activity_id),
  31          %Object{data: %{"reactions" => reactions}} when is_list(reactions) <-
  32            Object.normalize(activity, fetch: false) do
  33       reactions =
  34         reactions
  35         |> filter(params)
  36         |> filter_allowed_users(user, Map.get(params, :with_muted, false))
  37
  38       render(conn, "index.json", emoji_reactions: reactions, user: user)
  39     else
  40       _e -> json(conn, [])
  41     end
  42   end
  43
  44   def filter_allowed_users(reactions, user, with_muted) do
  45     exclude_ap_ids =
  46       if is_nil(user) do
  47         []
  48       else
  49         User.cached_blocked_users_ap_ids(user) ++
  50           if not with_muted, do: User.cached_muted_users_ap_ids(user), else: []
  51       end
  52
  53     filter_emoji = fn emoji, users ->
  54       case Enum.reject(users, &(&1 in exclude_ap_ids)) do
  55         [] -> nil
  56         users -> {emoji, users}
  57       end
  58     end
  59
  60     reactions
  61     |> Stream.map(fn
  62       [emoji, users] when is_list(users) -> filter_emoji.(emoji, users)
  63       {emoji, users} when is_list(users) -> filter_emoji.(emoji, users)
  64       _ -> nil
  65     end)
  66     |> Stream.reject(&is_nil/1)
  67   end
  68
  69   defp filter(reactions, %{emoji: emoji}) when is_binary(emoji) do
  70     Enum.filter(reactions, fn [e, _] -> e == emoji end)
  71   end
  72
  73   defp filter(reactions, _), do: reactions
  74
  75   def create(%{assigns: %{user: user}} = conn, %{id: activity_id, emoji: emoji}) do
  76     with {:ok, _activity} <- CommonAPI.react_with_emoji(activity_id, user, emoji) do
  77       activity = Activity.get_by_id(activity_id)
  78
  79       conn
  80       |> put_view(StatusView)
  81       |> render("show.json", activity: activity, for: user, as: :activity)
  82     end
  83   end
  84
  85   def delete(%{assigns: %{user: user}} = conn, %{id: activity_id, emoji: emoji}) do
  86     with {:ok, _activity} <- CommonAPI.unreact_with_emoji(activity_id, user, emoji) do
  87       activity = Activity.get_by_id(activity_id)
  88
  89       conn
  90       |> put_view(StatusView)
  91       |> render("show.json", activity: activity, for: user, as: :activity)
  92     end
  93   end
  94 end