Git of dcc - anni/blob - lib/pleroma/web/pleroma_api/controllers/settings_controller.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2022 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.PleromaAPI.SettingsController do
   6   use Pleroma.Web, :controller
   7
   8   alias Pleroma.Web.Plugs.OAuthScopesPlug
   9
  10   plug(Pleroma.Web.ApiSpec.CastAndValidate)
  11
  12   plug(
  13     OAuthScopesPlug,
  14     %{scopes: ["write:accounts"]} when action in [:update]
  15   )
  16
  17   plug(
  18     OAuthScopesPlug,
  19     %{scopes: ["read:accounts"]} when action in [:show]
  20   )
  21
  22   defdelegate open_api_operation(action), to: Pleroma.Web.ApiSpec.PleromaSettingsOperation
  23
  24   @doc "GET /api/v1/pleroma/settings/:app"
  25   def show(%{assigns: %{user: user}} = conn, %{app: app} = _params) do
  26     conn
  27     |> json(get_settings(user, app))
  28   end
  29
  30   @doc "PATCH /api/v1/pleroma/settings/:app"
  31   def update(%{assigns: %{user: user}, body_params: body_params} = conn, %{app: app} = _params) do
  32     settings =
  33       get_settings(user, app)
  34       |> merge_recursively(body_params)
  35
  36     with changeset <-
  37            Pleroma.User.update_changeset(
  38              user,
  39              %{pleroma_settings_store: %{app => settings}}
  40            ),
  41          {:ok, _} <- Pleroma.Repo.update(changeset) do
  42       conn
  43       |> json(settings)
  44     end
  45   end
  46
  47   defp merge_recursively(old, %{} = new) do
  48     old = ensure_object(old)
  49
  50     Enum.reduce(
  51       new,
  52       old,
  53       fn
  54         {k, nil}, acc ->
  55           Map.drop(acc, [k])
  56
  57         {k, %{} = new_child}, acc ->
  58           Map.put(acc, k, merge_recursively(acc[k], new_child))
  59
  60         {k, v}, acc ->
  61           Map.put(acc, k, v)
  62       end
  63     )
  64   end
  65
  66   defp get_settings(user, app) do
  67     user.pleroma_settings_store
  68     |> Map.get(app, %{})
  69     |> ensure_object()
  70   end
  71
  72   defp ensure_object(%{} = object) do
  73     object
  74   end
  75
  76   defp ensure_object(_) do
  77     %{}
  78   end
  79 end