Git of dcc - anni/blob - lib/pleroma/web/plugs/rate_limiter/limiter_supervisor.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2022 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.Plugs.RateLimiter.LimiterSupervisor do
   6   use DynamicSupervisor
   7
   8   import Cachex.Spec
   9
  10   def start_link(init_arg) do
  11     DynamicSupervisor.start_link(__MODULE__, init_arg, name: __MODULE__)
  12   end
  13
  14   def add_or_return_limiter(limiter_name, expiration) do
  15     result =
  16       DynamicSupervisor.start_child(
  17         __MODULE__,
  18         %{
  19           id: String.to_atom("rl_#{limiter_name}"),
  20           start:
  21             {Cachex, :start_link,
  22              [
  23                limiter_name,
  24                [
  25                  expiration:
  26                    expiration(
  27                      default: expiration,
  28                      interval: check_interval(expiration),
  29                      lazy: true
  30                    )
  31                ]
  32              ]}
  33         }
  34       )
  35
  36     case result do
  37       {:ok, _pid} = result -> result
  38       {:error, {:already_started, pid}} -> {:ok, pid}
  39       _ -> result
  40     end
  41   end
  42
  43   @impl true
  44   def init(_init_arg) do
  45     DynamicSupervisor.init(strategy: :one_for_one)
  46   end
  47
  48   defp check_interval(exp) do
  49     (exp / 2)
  50     |> Kernel.trunc()
  51     |> Kernel.min(5000)
  52     |> Kernel.max(1)
  53   end
  54 end