Git of dcc - anni/blob - lib/pleroma/workers/backup_worker.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2022 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Workers.BackupWorker do
   6   use Oban.Worker, queue: :backup, max_attempts: 1
   7
   8   alias Oban.Job
   9   alias Pleroma.User.Backup
  10
  11   def process(backup, admin_user_id \\ nil) do
  12     %{"op" => "process", "backup_id" => backup.id, "admin_user_id" => admin_user_id}
  13     |> new()
  14     |> Oban.insert()
  15   end
  16
  17   def schedule_deletion(backup) do
  18     days = Pleroma.Config.get([Backup, :purge_after_days])
  19     time = 60 * 60 * 24 * days
  20     scheduled_at = Calendar.NaiveDateTime.add!(backup.inserted_at, time)
  21
  22     %{"op" => "delete", "backup_id" => backup.id}
  23     |> new(scheduled_at: scheduled_at)
  24     |> Oban.insert()
  25   end
  26
  27   def delete(backup) do
  28     %{"op" => "delete", "backup_id" => backup.id}
  29     |> new()
  30     |> Oban.insert()
  31   end
  32
  33   @impl Oban.Worker
  34   def perform(%Job{
  35         args: %{"op" => "process", "backup_id" => backup_id, "admin_user_id" => admin_user_id}
  36       }) do
  37     with {:ok, %Backup{} = backup} <-
  38            backup_id |> Backup.get() |> Backup.process(),
  39          {:ok, _job} <- schedule_deletion(backup),
  40          :ok <- Backup.remove_outdated(backup),
  41          :ok <- maybe_deliver_email(backup, admin_user_id) do
  42       {:ok, backup}
  43     end
  44   end
  45
  46   def perform(%Job{args: %{"op" => "delete", "backup_id" => backup_id}}) do
  47     case Backup.get(backup_id) do
  48       %Backup{} = backup -> Backup.delete(backup)
  49       nil -> :ok
  50     end
  51   end
  52
  53   @impl Oban.Worker
  54   def timeout(_job), do: :timer.seconds(900)
  55
  56   defp has_email?(user) do
  57     not is_nil(user.email) and user.email != ""
  58   end
  59
  60   defp maybe_deliver_email(backup, admin_user_id) do
  61     has_mailer = Pleroma.Config.get([Pleroma.Emails.Mailer, :enabled])
  62     backup = backup |> Pleroma.Repo.preload(:user)
  63
  64     if has_email?(backup.user) and has_mailer do
  65       backup
  66       |> Pleroma.Emails.UserEmail.backup_is_ready_email(admin_user_id)
  67       |> Pleroma.Emails.Mailer.deliver()
  68
  69       :ok
  70     else
  71       :ok
  72     end
  73   end
  74 end