Git of dcc - anni/blob - lib/pleroma/workers/purge_expired_activity.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2022 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Workers.PurgeExpiredActivity do
   6   @moduledoc """
   7   Worker which purges expired activity.
   8   """
   9
  10   use Oban.Worker, queue: :activity_expiration, max_attempts: 1, unique: [period: :infinity]
  11
  12   import Ecto.Query
  13
  14   alias Pleroma.Activity
  15
  16   @spec enqueue(map()) ::
  17           {:ok, Oban.Job.t()}
  18           | {:error, :expired_activities_disabled}
  19           | {:error, :expiration_too_close}
  20   def enqueue(args) do
  21     with true <- enabled?() do
  22       {scheduled_at, args} = Map.pop(args, :expires_at)
  23
  24       args
  25       |> new(scheduled_at: scheduled_at)
  26       |> Oban.insert()
  27     end
  28   end
  29
  30   @impl true
  31   def perform(%Oban.Job{args: %{"activity_id" => id}}) do
  32     with %Activity{} = activity <- find_activity(id),
  33          %Pleroma.User{} = user <- find_user(activity.object.data["actor"]) do
  34       Pleroma.Web.CommonAPI.delete(activity.id, user)
  35     end
  36   end
  37
  38   @impl Oban.Worker
  39   def timeout(_job), do: :timer.seconds(5)
  40
  41   defp enabled? do
  42     with false <- Pleroma.Config.get([__MODULE__, :enabled], false) do
  43       {:error, :expired_activities_disabled}
  44     end
  45   end
  46
  47   defp find_activity(id) do
  48     with nil <- Activity.get_by_id_with_object(id) do
  49       {:error, :activity_not_found}
  50     end
  51   end
  52
  53   defp find_user(ap_id) do
  54     with nil <- Pleroma.User.get_by_ap_id(ap_id) do
  55       {:error, :user_not_found}
  56     end
  57   end
  58
  59   def get_expiration(id) do
  60     from(j in Oban.Job,
  61       where: j.state == "scheduled",
  62       where: j.queue == "activity_expiration",
  63       where: fragment("?->>'activity_id' = ?", j.args, ^id)
  64     )
  65     |> Pleroma.Repo.one()
  66   end
  67
  68   @spec expires_late_enough?(DateTime.t()) :: boolean()
  69   def expires_late_enough?(scheduled_at) do
  70     now = DateTime.utc_now()
  71     diff = DateTime.diff(scheduled_at, now, :millisecond)
  72     min_lifetime = Pleroma.Config.get([__MODULE__, :min_lifetime], 600)
  73     diff > :timer.seconds(min_lifetime)
  74   end
  75 end