Git of dcc - anni/blob - test/pleroma/web/mastodon_api/controllers/scheduled_activity_controller_test.exs

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2022 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MastodonAPI.ScheduledActivityControllerTest do
   6   use Pleroma.Web.ConnCase
   7
   8   alias Pleroma.Repo
   9   alias Pleroma.ScheduledActivity
  10
  11   import Pleroma.Factory
  12   import Ecto.Query
  13
  14   setup do: clear_config([ScheduledActivity, :enabled])
  15
  16   test "shows scheduled activities" do
  17     %{user: user, conn: conn} = oauth_access(["read:statuses"])
  18
  19     scheduled_activity_id1 = insert(:scheduled_activity, user: user).id |> to_string()
  20     scheduled_activity_id2 = insert(:scheduled_activity, user: user).id |> to_string()
  21     scheduled_activity_id3 = insert(:scheduled_activity, user: user).id |> to_string()
  22     scheduled_activity_id4 = insert(:scheduled_activity, user: user).id |> to_string()
  23
  24     # min_id
  25     conn_res = get(conn, "/api/v1/scheduled_statuses?limit=2&min_id=#{scheduled_activity_id1}")
  26
  27     result = json_response_and_validate_schema(conn_res, 200)
  28     assert [%{"id" => ^scheduled_activity_id3}, %{"id" => ^scheduled_activity_id2}] = result
  29
  30     # since_id
  31     conn_res = get(conn, "/api/v1/scheduled_statuses?limit=2&since_id=#{scheduled_activity_id1}")
  32
  33     result = json_response_and_validate_schema(conn_res, 200)
  34     assert [%{"id" => ^scheduled_activity_id4}, %{"id" => ^scheduled_activity_id3}] = result
  35
  36     # max_id
  37     conn_res = get(conn, "/api/v1/scheduled_statuses?limit=2&max_id=#{scheduled_activity_id4}")
  38
  39     result = json_response_and_validate_schema(conn_res, 200)
  40     assert [%{"id" => ^scheduled_activity_id3}, %{"id" => ^scheduled_activity_id2}] = result
  41   end
  42
  43   test "shows a scheduled activity" do
  44     %{user: user, conn: conn} = oauth_access(["read:statuses"])
  45     scheduled_activity = insert(:scheduled_activity, user: user)
  46
  47     res_conn = get(conn, "/api/v1/scheduled_statuses/#{scheduled_activity.id}")
  48
  49     assert %{"id" => scheduled_activity_id} = json_response_and_validate_schema(res_conn, 200)
  50     assert scheduled_activity_id == scheduled_activity.id |> to_string()
  51
  52     res_conn = get(conn, "/api/v1/scheduled_statuses/404")
  53
  54     assert %{"error" => "Record not found"} = json_response_and_validate_schema(res_conn, 404)
  55   end
  56
  57   test "updates a scheduled activity" do
  58     clear_config([ScheduledActivity, :enabled], true)
  59     %{user: user, conn: conn} = oauth_access(["write:statuses"])
  60
  61     scheduled_at = Timex.shift(NaiveDateTime.utc_now(), minutes: 60)
  62
  63     {:ok, scheduled_activity} =
  64       ScheduledActivity.create(
  65         user,
  66         %{
  67           scheduled_at: scheduled_at,
  68           params: build(:note).data
  69         }
  70       )
  71
  72     job = Repo.one(from(j in Oban.Job, where: j.queue == "scheduled_activities"))
  73
  74     assert job.args == %{"activity_id" => scheduled_activity.id}
  75     assert DateTime.truncate(job.scheduled_at, :second) == to_datetime(scheduled_at)
  76
  77     new_scheduled_at =
  78       NaiveDateTime.utc_now()
  79       |> Timex.shift(minutes: 120)
  80       |> Timex.format!("%Y-%m-%dT%H:%M:%S.%fZ", :strftime)
  81
  82     res_conn =
  83       conn
  84       |> put_req_header("content-type", "application/json")
  85       |> put("/api/v1/scheduled_statuses/#{scheduled_activity.id}", %{
  86         scheduled_at: new_scheduled_at
  87       })
  88
  89     assert %{"scheduled_at" => expected_scheduled_at} =
  90              json_response_and_validate_schema(res_conn, 200)
  91
  92     assert expected_scheduled_at == Pleroma.Web.CommonAPI.Utils.to_masto_date(new_scheduled_at)
  93     job = refresh_record(job)
  94
  95     assert DateTime.truncate(job.scheduled_at, :second) == to_datetime(new_scheduled_at)
  96
  97     res_conn =
  98       conn
  99       |> put_req_header("content-type", "application/json")
 100       |> put("/api/v1/scheduled_statuses/404", %{scheduled_at: new_scheduled_at})
 101
 102     assert %{"error" => "Record not found"} = json_response_and_validate_schema(res_conn, 404)
 103   end
 104
 105   test "deletes a scheduled activity" do
 106     clear_config([ScheduledActivity, :enabled], true)
 107     %{user: user, conn: conn} = oauth_access(["write:statuses"])
 108     scheduled_at = Timex.shift(NaiveDateTime.utc_now(), minutes: 60)
 109
 110     {:ok, scheduled_activity} =
 111       ScheduledActivity.create(
 112         user,
 113         %{
 114           scheduled_at: scheduled_at,
 115           params: build(:note).data
 116         }
 117       )
 118
 119     job = Repo.one(from(j in Oban.Job, where: j.queue == "scheduled_activities"))
 120
 121     assert job.args == %{"activity_id" => scheduled_activity.id}
 122
 123     res_conn =
 124       conn
 125       |> assign(:user, user)
 126       |> delete("/api/v1/scheduled_statuses/#{scheduled_activity.id}")
 127
 128     assert %{} = json_response_and_validate_schema(res_conn, 200)
 129     refute Repo.get(ScheduledActivity, scheduled_activity.id)
 130     refute Repo.get(Oban.Job, job.id)
 131
 132     res_conn =
 133       conn
 134       |> assign(:user, user)
 135       |> delete("/api/v1/scheduled_statuses/#{scheduled_activity.id}")
 136
 137     assert %{"error" => "Record not found"} = json_response_and_validate_schema(res_conn, 404)
 138   end
 139 end